From 2fd57282f0262ca084e05b0f2c63fbada395d02b Mon Sep 17 00:00:00 2001
From: V3n3RiX <venerix@koprulu.sector>
Date: Sun, 16 Jan 2022 20:27:28 +0000
Subject: gentoo resync : 16.01.2021

---
 sci-chemistry/votca/votca-2022.ebuild | 70 +++++++++++++++++++++++++++++++++++
 1 file changed, 70 insertions(+)
 create mode 100644 sci-chemistry/votca/votca-2022.ebuild

(limited to 'sci-chemistry/votca/votca-2022.ebuild')

diff --git a/sci-chemistry/votca/votca-2022.ebuild b/sci-chemistry/votca/votca-2022.ebuild
new file mode 100644
index 000000000000..f59f5347f3de
--- /dev/null
+++ b/sci-chemistry/votca/votca-2022.ebuild
@@ -0,0 +1,70 @@
+# Copyright 1999-2022 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=7
+
+inherit bash-completion-r1 cmake
+
+if [[ ${PV} == *9999 ]]; then
+	inherit git-r3
+	EGIT_REPO_URI="https://github.com/votca/votca.git"
+else
+	if [[ ${PV} = *_rc[1-9] ]]; then
+		MY_PV="${PV%%_rc*}-rc.${PV##*_rc}"
+	else
+		MY_PV="${PV}"
+	fi
+	SRC_URI="https://github.com/votca/votca/archive/v${MY_PV}.tar.gz -> ${P}.tar.gz"
+	KEYWORDS="~amd64 ~x86 ~amd64-linux"
+	S="${WORKDIR}/votca-${MY_PV}"
+fi
+
+DESCRIPTION="Versatile Object-oriented Toolkit for Coarse-graining Applications"
+HOMEPAGE="https://www.votca.org/"
+
+LICENSE="Apache-2.0"
+SLOT="0"
+IUSE="+gromacs test"
+RESTRICT="!test? ( test )"
+
+RDEPEND="
+	!sci-libs/votca-tools
+	!sci-chemistry/votca-csg
+	!sci-chemistry/votca-xtp
+	app-shells/bash:*
+	>=dev-cpp/eigen-3.3
+	dev-libs/boost:=
+	dev-libs/expat
+	sci-libs/fftw:3.0=
+	dev-lang/perl
+	gromacs? ( sci-chemistry/gromacs:= )
+	sci-libs/hdf5[cxx]
+	sci-libs/libxc
+	sci-libs/libint:2
+"
+DEPEND="${RDEPEND}"
+BDEPEND="virtual/pkgconfig"
+
+DOCS=( README.rst NOTICE.rst CHANGELOG.rst )
+
+src_configure() {
+	local mycmakeargs=(
+		-DENABLE_TESTING=$(usex test)
+		-DCMAKE_DISABLE_FIND_PACKAGE_GROMACS=$(usex !gromacs)
+		-DBUILD_CSGAPPS=ON
+		-DINSTALL_RC_FILES=OFF
+		-DCMAKE_DISABLE_FIND_PACKAGE_MKL=ON
+	)
+	cmake_src_configure
+}
+
+pkg_postinst() {
+	einfo
+	einfo "Please read and cite:"
+	einfo "VOTCA-XTP, J. Chem. Theo. Comp. 14, 6353 (2018)"
+	einfo "https://doi.org/10.1021/acs.jctc.8b00617"
+	einfo
+	einfo "VOTCA, J. Chem. Theory Comput. 5, 3211 (2009). "
+	einfo "https://dx.doi.org/10.1021/ct900369w"
+	einfo
+}
-- 
cgit v1.2.3