From d934827bf44b7cfcf6711964418148fa60877668 Mon Sep 17 00:00:00 2001
From: V3n3RiX <venerix@redcorelinux.org>
Date: Wed, 25 Nov 2020 22:39:15 +0000
Subject: gentoo resync : 25.11.2020

---
 sci-biology/lagan/lagan-2.0-r4.ebuild | 67 +++++++++++++++++++++++++++++++++++
 1 file changed, 67 insertions(+)
 create mode 100644 sci-biology/lagan/lagan-2.0-r4.ebuild

(limited to 'sci-biology/lagan/lagan-2.0-r4.ebuild')

diff --git a/sci-biology/lagan/lagan-2.0-r4.ebuild b/sci-biology/lagan/lagan-2.0-r4.ebuild
new file mode 100644
index 000000000000..4582d8f1078e
--- /dev/null
+++ b/sci-biology/lagan/lagan-2.0-r4.ebuild
@@ -0,0 +1,67 @@
+# Copyright 1999-2020 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=7
+
+inherit toolchain-funcs
+
+MY_P="lagan20"
+
+DESCRIPTION="The LAGAN suite of tools for whole-genome multiple alignment of genomic DNA"
+HOMEPAGE="http://lagan.stanford.edu/lagan_web/index.shtml"
+SRC_URI="http://lagan.stanford.edu/lagan_web/${MY_P}.tar.gz"
+
+LICENSE="GPL-2"
+SLOT="0"
+KEYWORDS="~amd64 ~x86"
+
+RDEPEND="dev-lang/perl"
+
+S="${WORKDIR}/${MY_P}"
+PATCHES=(
+	"${FILESDIR}"/${P}-makefile.patch
+	"${FILESDIR}"/${P}-conflicting-getline.patch
+	"${FILESDIR}"/${P}-gcc-4.8.patch
+	"${FILESDIR}"/${P}-ambiguous-end.patch
+	"${FILESDIR}"/${P}-gcc-9.patch
+	"${FILESDIR}"/${P}-gcc-10.patch
+	"${FILESDIR}"/${P}-C99-static-inline.patch
+	"${FILESDIR}"/${P}-qa-implicit-declarations.patch
+)
+
+src_prepare() {
+	default
+	sed -i "/use Getopt::Long;/ i use lib \"/usr/$(get_libdir)/lagan/lib\";" \
+		supermap.pl || die
+}
+
+src_configure() {
+	tc-export CC CXX
+}
+
+src_install() {
+	newbin lagan.pl lagan
+	newbin slagan.pl slagan
+	dobin mlagan
+	rm lagan.pl slagan.pl utils/Utils.pm || die
+
+	insinto /usr/$(get_libdir)/lagan/lib
+	doins Utils.pm
+
+	exeinto /usr/$(get_libdir)/lagan/utils
+	doexe utils/*
+
+	exeinto /usr/$(get_libdir)/lagan
+	doexe *.pl anchors chaos glocal order prolagan
+
+	insinto /usr/$(get_libdir)/lagan
+	doins *.txt
+
+	dosym ../$(get_libdir)/lagan/supermap.pl /usr/bin/supermap
+
+	newenvd - 99lagan <<- _EOF_
+		LAGAN_DIR="${EPREFIX}/usr/$(get_libdir)/lagan"
+	_EOF_
+
+	dodoc Readmes/README.*
+}
-- 
cgit v1.2.3