From 7218e1b46bceac05841e90472501742d905fb3fc Mon Sep 17 00:00:00 2001
From: V3n3RiX <venerix@redcorelinux.org>
Date: Fri, 12 Mar 2021 21:55:15 +0000
Subject: gentoo resync : 12.03.2021

---
 sci-biology/fasttree/fasttree-2.1.11.ebuild | 43 +++++++++++++++++++++++++++++
 1 file changed, 43 insertions(+)
 create mode 100644 sci-biology/fasttree/fasttree-2.1.11.ebuild

(limited to 'sci-biology/fasttree/fasttree-2.1.11.ebuild')

diff --git a/sci-biology/fasttree/fasttree-2.1.11.ebuild b/sci-biology/fasttree/fasttree-2.1.11.ebuild
new file mode 100644
index 000000000000..cb2d16791ee3
--- /dev/null
+++ b/sci-biology/fasttree/fasttree-2.1.11.ebuild
@@ -0,0 +1,43 @@
+# Copyright 1999-2021 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=7
+
+inherit cmake
+
+DESCRIPTION="Fast inference of approximately-maximum-likelihood phylogenetic trees"
+HOMEPAGE="http://www.microbesonline.org/fasttree/"
+SRC_URI="
+	http://www.microbesonline.org/fasttree/FastTree-${PV}.c
+	http://www.microbesonline.org/fasttree/FastTreeUPGMA.c -> FastTreeUPGMA-${PV}.c
+	http://www.microbesonline.org/fasttree/MOTreeComparison.tar.gz -> MOTreeComparison-${PV}.tar.gz
+"
+
+LICENSE="GPL-2"
+SLOT="0"
+KEYWORDS="~amd64 ~x86"
+IUSE="double-precision openmp cpu_flags_x86_sse3"
+
+REQUIRED_USE="?? ( double-precision cpu_flags_x86_sse3 )"
+
+DOCS=( README )
+
+PATCHES=( "${FILESDIR}"/${P}-format-security.patch )
+
+src_unpack() {
+	mkdir "${S}" || die
+	cd "${S}" || die
+	unpack ${A}
+	cp "${DISTDIR}"/{FastTreeUPGMA-${PV}.c,FastTree-${PV}.c} . || die
+	cp "${FILESDIR}"/CMakeLists.txt . || die
+}
+
+src_configure() {
+	local mycmakeargs=(
+		-DVERSION="${PV}"
+		-DHAS_SSE3=$(usex cpu_flags_x86_sse3)
+		-DUSE_OPENMP=$(usex openmp)
+		-DUSE_DOUBLE=$(usex double-precision)
+	)
+	cmake_src_configure
+}
-- 
cgit v1.2.3