From 3648761f2708fcf5662ea1b9585f594c36eefc30 Mon Sep 17 00:00:00 2001
From: V3n3RiX <venerix@koprulu.sector>
Date: Tue, 15 Aug 2023 21:27:56 +0100
Subject: gentoo auto-resync : 15:08:2023 - 21:27:55

---
 .../gnome-bluetooth/gnome-bluetooth-42.6.ebuild    | 71 ++++++++++++++++++++++
 1 file changed, 71 insertions(+)
 create mode 100644 net-wireless/gnome-bluetooth/gnome-bluetooth-42.6.ebuild

(limited to 'net-wireless/gnome-bluetooth/gnome-bluetooth-42.6.ebuild')

diff --git a/net-wireless/gnome-bluetooth/gnome-bluetooth-42.6.ebuild b/net-wireless/gnome-bluetooth/gnome-bluetooth-42.6.ebuild
new file mode 100644
index 000000000000..daa3d6f68d44
--- /dev/null
+++ b/net-wireless/gnome-bluetooth/gnome-bluetooth-42.6.ebuild
@@ -0,0 +1,71 @@
+# Copyright 1999-2023 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=8
+PYTHON_COMPAT=( python3_{10..11} )
+inherit gnome.org meson python-any-r1 xdg
+
+DESCRIPTION="Bluetooth graphical utilities integrated with GNOME"
+HOMEPAGE="https://wiki.gnome.org/Projects/GnomeBluetooth"
+
+LICENSE="GPL-2+ LGPL-2.1+ FDL-1.1+"
+SLOT="3/13" # subslot = libgnome-bluetooth-3 soname version
+IUSE="gtk-doc +introspection sendto test"
+RESTRICT="!test? ( test )"
+KEYWORDS="~amd64 ~arm ~arm64 ~loong ~ppc ~ppc64 ~riscv ~x86"
+
+DEPEND="
+	>=dev-libs/glib-2.44:2
+	>=gui-libs/gtk-4.4:4[introspection?]
+	media-libs/gsound
+	>=gui-libs/libadwaita-1.1:1
+	>=x11-libs/libnotify-0.7.0
+	virtual/libudev:=
+	>=sys-power/upower-0.99.14:=
+	introspection? ( >=dev-libs/gobject-introspection-1.54:= )
+"
+RDEPEND="${DEPEND}
+	acct-group/plugdev
+	virtual/udev
+	>=net-wireless/bluez-5
+	sendto? ( !net-wireless/gnome-bluetooth:2 )
+"
+BDEPEND="
+	${PYTHON_DEPS}
+	dev-libs/libxml2:2
+	dev-util/gdbus-codegen
+	dev-util/glib-utils
+	gtk-doc? ( >=dev-util/gtk-doc-1.9 )
+	virtual/pkgconfig
+	test? (
+		$(python_gen_any_dep '
+			>=dev-python/python-dbusmock-0.26.0[${PYTHON_USEDEP}]
+			dev-python/dbus-python[${PYTHON_USEDEP}]
+		')
+	)
+"
+
+python_check_deps() {
+	if use test; then
+		python_has_version ">=dev-python/python-dbusmock-0.26.0[${PYTHON_USEDEP}]" &&
+		python_has_version "dev-python/dbus-python[${PYTHON_USEDEP}]"
+	fi
+}
+
+pkg_setup() {
+	# Check for python is unconditional
+	python-any-r1_pkg_setup
+}
+
+src_configure() {
+	local emesonargs=(
+		$(meson_use sendto)
+		$(meson_use gtk-doc gtk_doc)
+		$(meson_use introspection)
+	)
+	meson_src_configure
+}
+
+pkg_postinst() {
+	xdg_pkg_postinst
+}
-- 
cgit v1.2.3