From 97f40b36b1afa9726e32962d11f3ac2d0bc5792e Mon Sep 17 00:00:00 2001
From: V3n3RiX <venerix@koprulu.sector>
Date: Thu, 16 Feb 2023 08:04:03 +0000
Subject: gentoo auto-resync : 16:02:2023 - 08:04:02

---
 net-wireless/bladerf/bladerf-2021.03-r1.ebuild | 69 ++++++++++++++++++++++++++
 1 file changed, 69 insertions(+)
 create mode 100644 net-wireless/bladerf/bladerf-2021.03-r1.ebuild

(limited to 'net-wireless/bladerf/bladerf-2021.03-r1.ebuild')

diff --git a/net-wireless/bladerf/bladerf-2021.03-r1.ebuild b/net-wireless/bladerf/bladerf-2021.03-r1.ebuild
new file mode 100644
index 000000000000..1f66fd37bef7
--- /dev/null
+++ b/net-wireless/bladerf/bladerf-2021.03-r1.ebuild
@@ -0,0 +1,69 @@
+# Copyright 1999-2023 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=8
+
+inherit cmake udev
+
+DESCRIPTION="Libraries for supporing the BladeRF hardware from Nuand"
+HOMEPAGE="https://nuand.com/"
+
+#lib is LGPL and cli tools are GPL
+LICENSE="GPL-2+ LGPL-2.1+"
+
+SLOT="0/${PV}"
+
+#maintainer notes:
+#doc use flag, looks like it can't be disabled right now and will
+#	always build if pandoc and help2man are installed
+#	also ignores when deps are missing and just disables docs
+IUSE="doc +tecla"
+
+MY_PN="bladeRF"
+
+if [[ ${PV} == "9999" ]] ; then
+	inherit git-r3
+	EGIT_REPO_URI="https://github.com/Nuand/${MY_PN}.git"
+else
+	MY_PV=${PV/\_/-}
+	S="${WORKDIR}/${MY_PN}-${MY_PV}"
+	SRC_URI="https://github.com/Nuand/${MY_PN}/archive/${MY_PV}.tar.gz -> ${P}.tar.gz \
+			https://github.com/analogdevicesinc/no-OS/archive/0bba46e6f6f75785a65d425ece37d0a04daf6157.tar.gz -> analogdevices-no-OS-0bba46.tar.gz"
+	KEYWORDS="amd64 ~arm ~riscv x86"
+fi
+
+BDEPEND="doc? ( app-doc/doxygen )"
+CDEPEND=">=dev-libs/libusb-1.0.16:1
+	tecla? ( dev-libs/libtecla )"
+DEPEND="${CDEPEND}
+	virtual/pkgconfig"
+RDEPEND="${CDEPEND}
+	>=net-wireless/bladerf-firmware-2.4.0
+	>=net-wireless/bladerf-fpga-0.12.0"
+
+src_unpack() {
+	if [ "${PV}" = "9999" ]; then
+		git-r3_src_unpack
+	else
+		default
+		mv "${WORKDIR}/no-OS-0bba46e6f6f75785a65d425ece37d0a04daf6157/ad9361" "${S}/thirdparty/analogdevicesinc/no-OS/" || die
+	fi
+}
+
+src_configure() {
+	local mycmakeargs=(
+		-DVERSION_INFO_OVERRIDE:STRING="${PV}"
+		-DBUILD_DOCUMENTATION="$(usex doc)"
+		-DENABLE_LIBTECLA="$(usex tecla)"
+		-DTREAT_WARNINGS_AS_ERRORS=OFF
+		-DUDEV_RULES_PATH="$(get_udevdir)"/rules.d
+	)
+	cmake_src_configure
+}
+
+pkg_postinst() {
+	udev_reload
+}
+pkg_postrm() {
+	udev_reload
+}
-- 
cgit v1.2.3