From 2018227e9344edb9da15fc6a4a8298086cc2aa77 Mon Sep 17 00:00:00 2001
From: V3n3RiX <venerix@redcorelinux.org>
Date: Sun, 2 Jun 2019 21:45:28 +0100
Subject: gentoo resync : 02.06.2019

---
 .../airdcpp-webclient-2.6.1.ebuild                 | 65 ++++++++++++++++++++++
 1 file changed, 65 insertions(+)
 create mode 100644 net-p2p/airdcpp-webclient/airdcpp-webclient-2.6.1.ebuild

(limited to 'net-p2p/airdcpp-webclient/airdcpp-webclient-2.6.1.ebuild')

diff --git a/net-p2p/airdcpp-webclient/airdcpp-webclient-2.6.1.ebuild b/net-p2p/airdcpp-webclient/airdcpp-webclient-2.6.1.ebuild
new file mode 100644
index 000000000000..647a9600c515
--- /dev/null
+++ b/net-p2p/airdcpp-webclient/airdcpp-webclient-2.6.1.ebuild
@@ -0,0 +1,65 @@
+# Copyright 1999-2019 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=7
+PYTHON_COMPAT=( pypy{,3} python{2_7,3_{5,6,7}} )
+
+inherit cmake-utils python-any-r1 user
+
+DESCRIPTION="Cross-platform Direct Connect client"
+HOMEPAGE="https://airdcpp-web.github.io/"
+SRC_URI="https://github.com/airdcpp-web/${PN}/archive/${PV}.tar.gz -> ${P}.tar.gz"
+
+KEYWORDS="~amd64 ~x86"
+LICENSE="GPL-2+"
+SLOT="0"
+IUSE="nat-pmp +tbb +webui"
+
+RDEPEND="
+	app-arch/bzip2
+	dev-cpp/websocketpp
+	dev-libs/boost:=
+	dev-libs/leveldb:=
+	dev-libs/libmaxminddb:=
+	dev-libs/openssl:0=[-bindist]
+	net-libs/miniupnpc:=
+	sys-libs/zlib:=
+	virtual/libiconv
+	nat-pmp? ( net-libs/libnatpmp:= )
+	tbb? ( dev-cpp/tbb:= )
+"
+DEPEND="
+	virtual/pkgconfig
+	${PYTHON_DEPS}
+	${RDEPEND}
+"
+PDEPEND="webui? ( www-apps/airdcpp-webui )"
+
+pkg_setup() {
+	python-any-r1_pkg_setup
+	enewgroup airdcppd
+	enewuser airdcppd -1 -1 /var/lib/airdcppd airdcppd
+}
+
+src_configure() {
+	local mycmakeargs=(
+		-DINSTALL_WEB_UI=OFF
+		-DENABLE_NATPMP=$(usex nat-pmp)
+		-DENABLE_TBB=$(usex tbb)
+	)
+	cmake-utils_src_configure
+}
+
+src_install() {
+	cmake-utils_src_install
+	newconfd "${FILESDIR}/airdcppd.confd" airdcppd
+	newinitd "${FILESDIR}/airdcppd.initd" airdcppd
+	keepdir /var/lib/airdcppd
+	fowners airdcppd:airdcppd /var/lib/airdcppd
+}
+
+pkg_postinst() {
+	if [[ -z "${REPLACING_VERSIONS}" ]]; then
+		elog "Run 'airdcppd --configure' to set up ports and authentication"
+	fi
+}
-- 
cgit v1.2.3