From 55b20c97078ded20d0e7c6b3ef33d673c861d8b4 Mon Sep 17 00:00:00 2001
From: V3n3RiX <venerix@koprulu.sector>
Date: Tue, 14 Mar 2023 00:16:43 +0000
Subject: gentoo auto-resync : 14:03:2023 - 00:16:42

---
 .../airdcpp-webclient-2.11.4.ebuild                | 61 ++++++++++++++++++++++
 1 file changed, 61 insertions(+)
 create mode 100644 net-p2p/airdcpp-webclient/airdcpp-webclient-2.11.4.ebuild

(limited to 'net-p2p/airdcpp-webclient/airdcpp-webclient-2.11.4.ebuild')

diff --git a/net-p2p/airdcpp-webclient/airdcpp-webclient-2.11.4.ebuild b/net-p2p/airdcpp-webclient/airdcpp-webclient-2.11.4.ebuild
new file mode 100644
index 000000000000..cf6f9ec68059
--- /dev/null
+++ b/net-p2p/airdcpp-webclient/airdcpp-webclient-2.11.4.ebuild
@@ -0,0 +1,61 @@
+# Copyright 1999-2023 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=8
+
+PYTHON_COMPAT=( pypy3 python3_{9..11} )
+
+inherit cmake python-any-r1 systemd
+
+DESCRIPTION="Cross-platform Direct Connect client"
+HOMEPAGE="https://airdcpp-web.github.io/"
+SRC_URI="https://github.com/airdcpp-web/${PN}/archive/${PV}.tar.gz -> ${P}.tar.gz"
+
+KEYWORDS="~amd64 ~riscv ~x86"
+LICENSE="GPL-2+"
+SLOT="0"
+IUSE="debug nat-pmp +tbb +webui"
+
+RDEPEND="
+	acct-user/airdcppd
+	acct-group/airdcppd
+	app-arch/bzip2
+	dev-cpp/websocketpp
+	dev-libs/boost:=
+	dev-libs/leveldb:=
+	dev-libs/libmaxminddb:=
+	dev-libs/openssl:0=[-bindist(-)]
+	net-libs/miniupnpc:=
+	sys-libs/zlib
+	virtual/libiconv
+	nat-pmp? ( net-libs/libnatpmp:= )
+	tbb? ( dev-cpp/tbb:= )
+"
+DEPEND="${RDEPEND}"
+BDEPEND="
+	virtual/pkgconfig
+	${PYTHON_DEPS}
+"
+PDEPEND="webui? ( www-apps/airdcpp-webui )"
+
+src_configure() {
+	local mycmakeargs=(
+		-DENABLE_NATPMP=$(usex nat-pmp)
+		-DENABLE_TBB=$(usex tbb)
+		-DINSTALL_WEB_UI=OFF
+	)
+	CMAKE_BUILD_TYPE=$(usex debug Debug Gentoo) cmake_src_configure
+}
+
+src_install() {
+	cmake_src_install
+	newconfd "${FILESDIR}/airdcppd.confd" airdcppd
+	newinitd "${FILESDIR}/airdcppd.initd" airdcppd
+	systemd_dounit "${FILESDIR}/airdcppd.service"
+}
+
+pkg_postinst() {
+	if [[ -z "${REPLACING_VERSIONS}" ]]; then
+		elog "Run 'airdcppd --configure' to set up ports and authentication"
+	fi
+}
-- 
cgit v1.2.3