From 78df2aa7ae35e69cd91f555197f771fcd59f196c Mon Sep 17 00:00:00 2001
From: V3n3RiX <venerix@koprulu.sector>
Date: Sat, 19 Aug 2023 21:39:30 +0100
Subject: gentoo auto-resync : 19:08:2023 - 21:39:30

---
 net-nds/ldapvi/ldapvi-1.7_p20101214-r5.ebuild | 59 +++++++++++++++++++++++++++
 1 file changed, 59 insertions(+)
 create mode 100644 net-nds/ldapvi/ldapvi-1.7_p20101214-r5.ebuild

(limited to 'net-nds/ldapvi/ldapvi-1.7_p20101214-r5.ebuild')

diff --git a/net-nds/ldapvi/ldapvi-1.7_p20101214-r5.ebuild b/net-nds/ldapvi/ldapvi-1.7_p20101214-r5.ebuild
new file mode 100644
index 000000000000..be2ce0f73d2f
--- /dev/null
+++ b/net-nds/ldapvi/ldapvi-1.7_p20101214-r5.ebuild
@@ -0,0 +1,59 @@
+# Copyright 1999-2023 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=8
+
+inherit autotools
+
+DESCRIPTION="Manage LDAP entries with a text editor"
+HOMEPAGE="http://www.lichteblau.com/ldapvi/"
+SRC_URI="mirror://gentoo/${P}.tar.bz2"
+S="${WORKDIR}"/${P}/${PN}
+
+LICENSE="GPL-2"
+SLOT="0"
+KEYWORDS="amd64 ~hppa ~ppc ~sparc x86"
+IUSE="gnutls sasl"
+
+RDEPEND="
+	dev-libs/popt
+	dev-libs/glib:2
+	sys-libs/readline:=
+	sys-libs/ncurses:=
+	virtual/libcrypt:=
+	gnutls? (
+		net-libs/gnutls:=
+		net-nds/openldap[gnutls]
+	)
+	!gnutls? (
+		dev-libs/openssl:=
+		net-nds/openldap[ssl]
+	)
+	sasl? ( dev-libs/cyrus-sasl:2[ssl] )
+"
+DEPEND="${RDEPEND}"
+BDEPEND="virtual/pkgconfig"
+
+PATCHES=( "${FILESDIR}/${PN}-1.7-fix-implicit-function-declarations.patch" )
+
+src_prepare() {
+	default
+
+	# bug #459478
+	sed -i \
+		-e '/^AC_SEARCH_LIBS/s:curses ncurses:curses ncurses tinfo:' \
+		configure.in || die
+
+	eautoreconf
+}
+
+src_configure() {
+	econf \
+		--with-libcrypto=$(usex gnutls gnutls openssl)
+}
+
+src_install() {
+	dobin ldapvi
+	doman ldapvi.1
+	dodoc NEWS manual/{bg.png,html.xsl,manual.{css,xml}}
+}
-- 
cgit v1.2.3