From 57dda344760f34c8c8f93c3c161ab10e55dc3860 Mon Sep 17 00:00:00 2001
From: V3n3RiX <venerix@koprulu.sector>
Date: Sun, 23 Apr 2023 12:07:24 +0100
Subject: gentoo auto-resync : 23:04:2023 - 12:07:24

---
 net-misc/sstp-client/sstp-client-1.0.18-r2.ebuild | 67 +++++++++++++++++++++++
 1 file changed, 67 insertions(+)
 create mode 100644 net-misc/sstp-client/sstp-client-1.0.18-r2.ebuild

(limited to 'net-misc/sstp-client/sstp-client-1.0.18-r2.ebuild')

diff --git a/net-misc/sstp-client/sstp-client-1.0.18-r2.ebuild b/net-misc/sstp-client/sstp-client-1.0.18-r2.ebuild
new file mode 100644
index 000000000000..d3fbceca2f8f
--- /dev/null
+++ b/net-misc/sstp-client/sstp-client-1.0.18-r2.ebuild
@@ -0,0 +1,67 @@
+# Copyright 1999-2023 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=8
+
+inherit autotools linux-info
+
+DESCRIPTION="Client implementation of Secure Socket Tunneling Protocol (SSTP)"
+HOMEPAGE="https://sstp-client.sourceforge.net/"
+SRC_URI="mirror://sourceforge/sstp-client/${P}.tar.gz"
+SRC_URI+=" https://dev.gentoo.org/~sam/distfiles/${CATEGORY}/${PN}/${P}-ppp-2.5.0-patches.tar.xz"
+
+LICENSE="GPL-2+-with-openssl-exception"
+SLOT="0"
+KEYWORDS="~amd64 ~arm ~arm64 ~x86"
+IUSE="static"
+
+DEPEND="dev-libs/libevent:=
+	dev-libs/openssl:=
+	net-dialup/ppp:="
+RDEPEND="${DEPEND}
+	acct-group/sstpc
+	acct-user/sstpc"
+BDEPEND="virtual/pkgconfig"
+
+CONFIG_CHECK="~NETFILTER_NETLINK"
+
+DOCS=( AUTHORS ChangeLog DEVELOPERS NEWS README TODO USING )
+
+PATCHES=(
+	"${FILESDIR}/${PN}-1.0.12-remove-network-test.patch"
+	"${FILESDIR}/${PN}-1.0.12-fix-example.patch"
+
+	"${FILESDIR}/${PN}-1.0.18-includes.patch"
+	"${WORKDIR}/${P}-ppp-2.5.0-patches"
+)
+
+src_prepare() {
+	default
+
+	eautoreconf
+}
+
+src_configure() {
+	local PPPD_VER="$(best_version net-dialup/ppp)"
+	# Reduce it to ${PV}-${PR}
+	PPPD_VER=${PPPD_VER#*/*-}
+	# Main version without beta/pre/patch/revision
+	PPPD_VER=${PPPD_VER%%[_-]*}
+
+	local myeconfargs=(
+		--enable-ppp-plugin
+		--enable-group=sstpc
+		--enable-user=sstpc
+		--with-pppd-plugin-dir="/usr/$(get_libdir)/pppd/${PPPD_VER}"
+		--with-runtime-dir="/run/sstpc"
+		$(use_enable static)
+	)
+
+	econf "${myeconfargs[@]}"
+}
+
+src_install() {
+	default
+
+	find "${ED}" -name '*.la' -delete || die
+}
-- 
cgit v1.2.3