From e5346f2f512bd7faf413f3de3ef7fbcfbcd974b3 Mon Sep 17 00:00:00 2001
From: V3n3RiX <venerix@koprulu.sector>
Date: Sun, 28 May 2023 15:14:55 +0100
Subject: gentoo auto-resync : 28:05:2023 - 15:14:55

---
 net-misc/seafile/seafile-9.0.2_p1.ebuild | 65 ++++++++++++++++++++++++++++++++
 1 file changed, 65 insertions(+)
 create mode 100644 net-misc/seafile/seafile-9.0.2_p1.ebuild

(limited to 'net-misc/seafile/seafile-9.0.2_p1.ebuild')

diff --git a/net-misc/seafile/seafile-9.0.2_p1.ebuild b/net-misc/seafile/seafile-9.0.2_p1.ebuild
new file mode 100644
index 000000000000..4b8ab33574ed
--- /dev/null
+++ b/net-misc/seafile/seafile-9.0.2_p1.ebuild
@@ -0,0 +1,65 @@
+# Copyright 1999-2023 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=8
+
+PYTHON_COMPAT=( python3_{9..11} )
+
+# Upstream is moving tags repeatedly, then we use commit hash.
+RELEASE_COMMIT="f3b2eb7372eabcf1d1c267d8ed4a72fa8be5e1e3"
+
+inherit autotools python-single-r1 vala
+
+DESCRIPTION="File syncing and sharing software with file encryption and group sharing"
+HOMEPAGE="https://www.seafile.com/ https://github.com/haiwen/seafile/"
+SRC_URI="https://github.com/haiwen/${PN}/archive/${RELEASE_COMMIT}.tar.gz -> ${P}.tar.gz"
+
+LICENSE="GPL-2+-with-openssl-exception"
+SLOT="0"
+KEYWORDS="~amd64 ~x86"
+REQUIRED_USE="${PYTHON_REQUIRED_USE}"
+
+RDEPEND="${PYTHON_DEPS}
+	$(python_gen_cond_dep '
+		dev-python/future[${PYTHON_USEDEP}]
+	')
+	dev-libs/openssl:=
+	dev-db/sqlite:3
+	dev-libs/glib:2
+	dev-libs/jansson:=
+	dev-libs/libevent:=
+	net-libs/libsearpc[${PYTHON_SINGLE_USEDEP}]
+	net-libs/libwebsockets[client]
+	net-misc/curl
+	sys-apps/util-linux
+	sys-libs/zlib
+	elibc_musl? ( sys-libs/fts-standalone )"
+DEPEND="${RDEPEND}"
+BDEPEND="${PYTHON_DEPS}
+	$(vala_depend)"
+
+S="${WORKDIR}/${PN}-${RELEASE_COMMIT}"
+
+pkg_setup() {
+	python-single-r1_pkg_setup
+	vala_setup
+}
+
+src_prepare() {
+	default
+	eautoreconf
+}
+
+src_configure() {
+	local myeconfargs=(
+		--disable-static
+	)
+	econf "${myeconfargs[@]}"
+}
+
+src_install() {
+	default
+	# Remove unnecessary .la files
+	find "${ED}" -name '*.la' -delete || die
+	python_fix_shebang "${ED}"/usr/bin/seaf-cli
+}
-- 
cgit v1.2.3