From 38f60b3ec9ff175535d9a056a76ae42931e61e21 Mon Sep 17 00:00:00 2001
From: V3n3RiX <venerix@redcorelinux.org>
Date: Thu, 16 Nov 2017 16:56:41 +0000
Subject: gentoo resync : 16.11.2017

---
 net-misc/seafile/seafile-6.1.3.ebuild | 43 +++++++++++++++++++++++++++++++++++
 1 file changed, 43 insertions(+)
 create mode 100644 net-misc/seafile/seafile-6.1.3.ebuild

(limited to 'net-misc/seafile/seafile-6.1.3.ebuild')

diff --git a/net-misc/seafile/seafile-6.1.3.ebuild b/net-misc/seafile/seafile-6.1.3.ebuild
new file mode 100644
index 000000000000..8c268d75d841
--- /dev/null
+++ b/net-misc/seafile/seafile-6.1.3.ebuild
@@ -0,0 +1,43 @@
+# Copyright 1999-2017 Gentoo Foundation
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=6
+PYTHON_COMPAT=( python2_7 )
+inherit autotools python-single-r1 vala
+
+DESCRIPTION="File syncing and sharing software with file encryption and group sharing"
+HOMEPAGE="https://github.com/haiwen/seafile/ http://www.seafile.com/"
+SRC_URI="https://github.com/haiwen/${PN}/archive/v${PV}.tar.gz -> ${P}.tar.gz"
+
+LICENSE="GPL-2+-with-openssl-exception"
+SLOT="0"
+KEYWORDS="~amd64 ~x86"
+IUSE=""
+REQUIRED_USE="${PYTHON_REQUIRED_USE}"
+
+RDEPEND="${PYTHON_DEPS}
+	net-libs/libsearpc[${PYTHON_USEDEP}]
+	=net-libs/ccnet-${PV}[${PYTHON_USEDEP}]
+	>=dev-libs/glib-2.16.0:2
+	>=dev-libs/libevent-2.0
+	>=dev-libs/jansson-2.2.1
+	>=sys-libs/zlib-1.2.0
+	>=net-misc/curl-7.17
+	dev-libs/openssl:0=
+	dev-db/sqlite:3"
+DEPEND="${RDEPEND}
+	$(vala_depend)"
+
+src_prepare() {
+	default
+	sed -i -e 's/valac /${VALAC} /' lib/Makefile.am || die
+	eautoreconf
+	vala_src_prepare
+}
+
+src_install() {
+	default
+	# Remove unnecessary .la files, as recommended by ltprune.eclass
+	find "${ED}" -name '*.la' -delete || die
+	python_fix_shebang "${ED}"usr/bin
+}
-- 
cgit v1.2.3