From 36ac65103bf5503e5bad1ecc7e8cb9e7643f6840 Mon Sep 17 00:00:00 2001
From: V3n3RiX <venerix@redcorelinux.org>
Date: Fri, 13 Sep 2019 17:49:31 +0100
Subject: Revert "gentoo resync : 13.09.2019"

This reverts commit a1392efe64137262023d92492396ca9156d22396.
---
 .../seafile-client/seafile-client-6.1.7.ebuild     | 57 ++++++++++++++++++++++
 1 file changed, 57 insertions(+)
 create mode 100644 net-misc/seafile-client/seafile-client-6.1.7.ebuild

(limited to 'net-misc/seafile-client/seafile-client-6.1.7.ebuild')

diff --git a/net-misc/seafile-client/seafile-client-6.1.7.ebuild b/net-misc/seafile-client/seafile-client-6.1.7.ebuild
new file mode 100644
index 000000000000..08b04cd8efc6
--- /dev/null
+++ b/net-misc/seafile-client/seafile-client-6.1.7.ebuild
@@ -0,0 +1,57 @@
+# Copyright 1999-2017 Gentoo Foundation
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=6
+inherit cmake-utils gnome2-utils
+
+DESCRIPTION="Seafile desktop client"
+HOMEPAGE="https://github.com/haiwen/seafile-client/ http://www.seafile.com/"
+SRC_URI="https://github.com/haiwen/${PN}/archive/v${PV}.tar.gz -> ${P}.tar.gz"
+
+LICENSE="Apache-2.0"
+SLOT="0"
+KEYWORDS="~amd64 ~x86"
+IUSE="shibboleth test"
+
+RDEPEND="net-libs/libsearpc
+	=net-libs/ccnet-${PV}
+	=net-misc/seafile-${PV}
+	dev-libs/libevent
+	dev-libs/jansson
+	dev-libs/openssl:0
+	dev-db/sqlite:3
+	dev-qt/qtcore:5
+	dev-qt/qtgui:5
+	dev-qt/qtwidgets:5
+	dev-qt/qtnetwork:5
+	dev-qt/qtdbus:5
+	shibboleth? ( || ( dev-qt/qtwebengine:5[widgets] dev-qt/qtwebkit:5 ) )"
+DEPEND="${RDEPEND}
+	dev-qt/linguist-tools:5
+	test? ( dev-qt/qttest:5 )"
+
+src_prepare() {
+	eapply "${FILESDIR}/${PN}-select-qt5.patch"
+	cmake-utils_src_prepare
+	if use shibboleth ; then
+		if ! has_version "dev-qt/qtwebengine:5[widgets]" ; then
+			sed -i -e 's/IF(WIN32 OR DETECTED_QT_VERSION VERSION_LESS 5.6.0)/IF(TRUE)/' CMakeLists.txt || die
+		fi
+	fi
+}
+
+src_configure() {
+	local mycmakeargs=(
+		-DBUILD_SHIBBOLETH_SUPPORT="$(usex shibboleth)"
+		-DBUILD_TESTING="$(usex test)"
+	)
+	cmake-utils_src_configure
+}
+
+pkg_postinst() {
+	gnome2_icon_cache_update
+}
+
+pkg_postrm() {
+	gnome2_icon_cache_update
+}
-- 
cgit v1.2.3