From d7ed2b01311f15ba54fe8ea872aab7d59ab2b193 Mon Sep 17 00:00:00 2001
From: V3n3RiX <venerix@redcorelinux.org>
Date: Fri, 29 Jan 2021 18:03:51 +0000
Subject: gentoo resync : 29.01.2021

---
 net-misc/remmina/Manifest                 |  1 +
 net-misc/remmina/remmina-1.4.10-r1.ebuild | 99 +++++++++++++++++++++++++++++++
 2 files changed, 100 insertions(+)
 create mode 100644 net-misc/remmina/remmina-1.4.10-r1.ebuild

(limited to 'net-misc/remmina')

diff --git a/net-misc/remmina/Manifest b/net-misc/remmina/Manifest
index c56787ff7461..1a496c6c6927 100644
--- a/net-misc/remmina/Manifest
+++ b/net-misc/remmina/Manifest
@@ -1,3 +1,4 @@
 DIST Remmina-v1.4.10.tar.gz 2072202 BLAKE2B 38b6a3cca9b5956a252d4d4433910d46d0d36a2232a2a107b1e556f118f3b1a6d3c02b0bea26a39a52d572c1380dbb5bdac1acd8d6ba07c97b9acc9a64a9142f SHA512 89fed0b0ed17ac1db57a1d9ad33b80f4d17f6cfb4ff7db9b6434d9d4dabf708971e4d93dd573dbf606d1899311e564f159a656223d66bc4a9d7a15a29b5b5963
+EBUILD remmina-1.4.10-r1.ebuild 2532 BLAKE2B 8f81ab82ed4a7376650ffb1f58aa3c585200fdb035c0f45932703d7fa35ddb91bf1d8885825d8938d094429a18f7ff393b7b335d3c2ae7addeaeb409d46f29e8 SHA512 a70677a1ff8074fc13cd340a9ffcdc7569ac8b5fad6cdb77c4c26ab9a323408a4f2a024d1684ae9fde318044cfd1c74439c14af4299122876ab07abf3ce64dfd
 EBUILD remmina-1.4.10.ebuild 2500 BLAKE2B 966b7a8753277b7b2494582eda605c337a13456afdb907195f730f5cddbbde7701edb6edfadd08383a8cb32134be815fa67bc62ab93628e980bcbef8658189fb SHA512 52b13e1bc91d55a991eb3967b5a676ee82debe3856153058d5ec222d1bc5c59ff04b772ae1439a2b9cbc890d3d9ebdb19ab3cbe7c0086a77d86c392bafa33fc5
 MISC metadata.xml 1084 BLAKE2B e4bb4c696f1ef71959b779ccad19d3ee380a6e846e42b1e02caf2a772df07d168bb9623b8f29cfdcc7fb37f60523e6c1fc471f016ea3437c18b3e7512a4bcad4 SHA512 c0b50eca7d4cdd6dfa201aabec7c195b7dca44938ee627919a000bdc47fc95acd4107936a61399fab2c78dfcd3b97ce06753e97fc6bb21015758afe91337a346
diff --git a/net-misc/remmina/remmina-1.4.10-r1.ebuild b/net-misc/remmina/remmina-1.4.10-r1.ebuild
new file mode 100644
index 000000000000..42c9eab621b2
--- /dev/null
+++ b/net-misc/remmina/remmina-1.4.10-r1.ebuild
@@ -0,0 +1,99 @@
+# Copyright 1999-2021 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=7
+
+inherit cmake optfeature xdg
+
+MY_P="${PN^}-v${PV}"
+
+DESCRIPTION="A GTK+ RDP, SPICE, VNC, XDMCP and SSH client"
+HOMEPAGE="https://remmina.org/"
+SRC_URI="https://gitlab.com/Remmina/Remmina/-/archive/v${PV}/${MY_P}.tar.gz"
+
+LICENSE="GPL-2+-with-openssl-exception"
+SLOT="0"
+KEYWORDS="~amd64 ~arm64 ~x86"
+IUSE="appindicator crypt cups examples gnome-keyring kwallet libressl nls spice ssh rdp telemetry telepathy vnc webkit zeroconf"
+
+DEPEND="
+	app-emulation/spice-protocol
+	dev-libs/glib:2
+	dev-libs/json-glib
+	dev-libs/libsodium:=
+	net-libs/libsoup
+	x11-libs/gdk-pixbuf
+	x11-libs/gtk+:3
+	x11-libs/libX11
+	x11-libs/libxkbfile
+	appindicator? ( dev-libs/libappindicator:3 )
+	crypt? ( dev-libs/libgcrypt:0= )
+	rdp? ( >=net-misc/freerdp-2.0.0_rc4_p1129[X]
+		<net-misc/freerdp-3[X]
+		cups? ( net-print/cups:= ) )
+	gnome-keyring? ( app-crypt/libsecret )
+	kwallet? ( kde-frameworks/kwallet )
+	!libressl? ( dev-libs/openssl:0= )
+	libressl? ( dev-libs/libressl:0= )
+	spice? ( net-misc/spice-gtk[gtk3] )
+	ssh? ( net-libs/libssh:0=[sftp]
+		x11-libs/vte:2.91 )
+	telepathy? ( net-libs/telepathy-glib )
+	vnc? ( net-libs/libvncserver[jpeg] )
+	webkit? ( net-libs/webkit-gtk:4 )
+	zeroconf? ( >=net-dns/avahi-0.8-r2[dbus,gtk] )
+"
+BDEPEND="
+	dev-util/intltool
+	virtual/pkgconfig
+	nls? ( sys-devel/gettext )
+"
+
+RDEPEND="
+	${DEPEND}
+	virtual/freedesktop-icon-theme
+"
+
+DOCS=( AUTHORS CHANGELOG.md README.md THANKS.md )
+
+S="${WORKDIR}/${MY_P}"
+
+src_prepare() {
+	xdg_environment_reset
+	cmake_src_prepare
+}
+
+src_configure() {
+	local mycmakeargs=(
+		-DWITH_APPINDICATOR=$(usex appindicator)
+		-DWITH_GCRYPT=$(usex crypt)
+		-DWITH_EXAMPLES=$(usex examples)
+		-DWITH_LIBSECRET=$(usex gnome-keyring)
+		-DWITH_KF5WALLET=$(usex kwallet)
+		-DWITH_GETTEXT=$(usex nls)
+		-DWITH_TRANSLATIONS=$(usex nls)
+		-DWITH_FREERDP=$(usex rdp)
+		-DWITH_CUPS=$(usex cups)
+		-DWITH_SPICE=$(usex spice)
+		-DWITH_LIBSSH=$(usex ssh)
+		-DWITH_VTE=$(usex ssh)
+		-DWITH_TELEPATHY=$(usex telepathy)
+		-DWITH_LIBVNCSERVER=$(usex vnc)
+		-DWITH_WWW=$(usex webkit)
+		-DWITH_AVAHI=$(usex zeroconf)
+		-DWITH_NEWS=$(usex telemetry)
+		-DWITH_ICON_CACHE=OFF
+		-DWITH_UPDATE_DESKTOP_DB=OFF
+	)
+	cmake_src_configure
+}
+
+pkg_postinst() {
+	xdg_pkg_postinst
+
+	elog "To get additional features, some optional runtime dependencies"
+	elog "may be installed:"
+	elog ""
+	optfeature "encrypted VNC connections" net-libs/libvncserver[gcrypt]
+	optfeature "XDMCP support" x11-base/xorg-server[xephyr]
+}
-- 
cgit v1.2.3