From b24bd25253fe093f722ab576d29fdc41d04cb1ee Mon Sep 17 00:00:00 2001
From: V3n3RiX <venerix@redcorelinux.org>
Date: Fri, 2 Aug 2019 19:14:55 +0100
Subject: gentoo resync : 02.08.2019

---
 net-misc/remmina/remmina-1.3.5_p20190731.ebuild | 94 +++++++++++++++++++++++++
 1 file changed, 94 insertions(+)
 create mode 100644 net-misc/remmina/remmina-1.3.5_p20190731.ebuild

(limited to 'net-misc/remmina/remmina-1.3.5_p20190731.ebuild')

diff --git a/net-misc/remmina/remmina-1.3.5_p20190731.ebuild b/net-misc/remmina/remmina-1.3.5_p20190731.ebuild
new file mode 100644
index 000000000000..c2cca7a2478a
--- /dev/null
+++ b/net-misc/remmina/remmina-1.3.5_p20190731.ebuild
@@ -0,0 +1,94 @@
+# Copyright 1999-2019 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=6
+
+inherit cmake-utils eutils gnome2-utils vcs-snapshot xdg-utils
+
+MY_P="${PN^}-v${PV}"
+COMMIT="d3cfd641333b45ffb160dab2080fda3f4bbb8d68"
+
+DESCRIPTION="A GTK+ RDP, SPICE, VNC, XDMCP and SSH client"
+HOMEPAGE="https://remmina.org/"
+SRC_URI="https://gitlab.com/Remmina/Remmina/-/archive/master/${COMMIT}.tar.gz -> ${P}.tar.gz"
+
+LICENSE="GPL-2+-with-openssl-exception"
+SLOT="0"
+KEYWORDS="~amd64 ~x86"
+IUSE="ayatana crypt examples gnome-keyring kwallet libressl nls spice ssh rdp telepathy vnc webkit zeroconf"
+
+CDEPEND="
+	dev-libs/glib:2
+	dev-libs/json-glib
+	dev-libs/libsodium:=
+	net-libs/libsoup
+	x11-libs/gdk-pixbuf
+	x11-libs/gtk+:3
+	x11-libs/libX11
+	x11-libs/libxkbfile
+	ayatana? ( dev-libs/libappindicator:3 )
+	crypt? ( dev-libs/libgcrypt:0= )
+	rdp? ( >=net-misc/freerdp-2.0.0_rc4 )
+	gnome-keyring? ( app-crypt/libsecret )
+	kwallet? ( kde-frameworks/kwallet )
+	!libressl? ( dev-libs/openssl:0= )
+	libressl? ( dev-libs/libressl:0= )
+	spice? ( net-misc/spice-gtk[gtk3] )
+	ssh? ( net-libs/libssh:0=[sftp]
+		x11-libs/vte:2.91 )
+	telepathy? ( net-libs/telepathy-glib )
+	vnc? ( net-libs/libvncserver[jpeg] )
+	webkit? ( net-libs/webkit-gtk:4 )
+	zeroconf? ( net-dns/avahi[gtk3] )
+"
+DEPEND="${CDEPEND}
+	dev-util/intltool
+	virtual/pkgconfig
+	nls? ( sys-devel/gettext )
+"
+RDEPEND="${CDEPEND}
+	virtual/freedesktop-icon-theme
+"
+
+DOCS=( AUTHORS CHANGELOG.md README.md THANKS.md )
+
+src_configure() {
+	local mycmakeargs=(
+		-DWITH_APPINDICATOR=$(usex ayatana)
+		-DWITH_GCRYPT=$(usex crypt)
+		-DWITH_EXAMPLES=$(usex examples)
+		-DWITH_LIBSECRET=$(usex gnome-keyring)
+		-DWITH_KF5WALLET=$(usex kwallet)
+		-DWITH_GETTEXT=$(usex nls)
+		-DWITH_TRANSLATIONS=$(usex nls)
+		-DWITH_FREERDP=$(usex rdp)
+		-DWITH_SPICE=$(usex spice)
+		-DWITH_LIBSSH=$(usex ssh)
+		-DWITH_VTE=$(usex ssh)
+		-DWITH_TELEPATHY=$(usex telepathy)
+		-DWITH_LIBVNCSERVER=$(usex vnc)
+		-DWITH_WWW=$(usex webkit)
+		-DWITH_AVAHI=$(usex zeroconf)
+		-DWITH_ICON_CACHE=OFF
+		-DWITH_UPDATE_DESKTOP_DB=OFF
+	)
+	cmake-utils_src_configure
+}
+
+pkg_postinst() {
+	gnome2_icon_cache_update
+	xdg_mimeinfo_database_update
+	xdg_desktop_database_update
+
+	elog "To get additional features, some optional runtime dependencies"
+	elog "may be installed:"
+	elog ""
+	optfeature "encrypted VNC connections" net-libs/libvncserver[gcrypt]
+	optfeature "XDMCP support" x11-base/xorg-server[xephyr]
+}
+
+pkg_postrm() {
+	gnome2_icon_cache_update
+	xdg_mimeinfo_database_update
+	xdg_desktop_database_update
+}
-- 
cgit v1.2.3