From 0f558761aa2dee1017b4751e4017205e015a9560 Mon Sep 17 00:00:00 2001
From: V3n3RiX <venerix@koprulu.sector>
Date: Wed, 29 Jun 2022 12:04:12 +0100
Subject: gentoo resync : 29.12.2022

---
 net-misc/putty/putty-0.77.ebuild | 92 ++++++++++++++++++++++++++++++++++++++++
 1 file changed, 92 insertions(+)
 create mode 100644 net-misc/putty/putty-0.77.ebuild

(limited to 'net-misc/putty/putty-0.77.ebuild')

diff --git a/net-misc/putty/putty-0.77.ebuild b/net-misc/putty/putty-0.77.ebuild
new file mode 100644
index 000000000000..a09ae7ae4600
--- /dev/null
+++ b/net-misc/putty/putty-0.77.ebuild
@@ -0,0 +1,92 @@
+# Copyright 1999-2022 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=8
+inherit cmake desktop xdg-utils
+
+DESCRIPTION="A Free Telnet/SSH Client"
+HOMEPAGE="https://www.chiark.greenend.org.uk/~sgtatham/putty/"
+SRC_URI="https://dev.gentoo.org/~polynomial-c/${PN}-icons.tar.bz2"
+if [[ ${PV} == *9999 ]] ; then
+	inherit git-r3
+	EGIT_REPO_URI="https://git.tartarus.org/simon/putty.git"
+else
+	SRC_URI+=" https://the.earth.li/~sgtatham/${PN}/${PV}/${P}.tar.gz"
+	KEYWORDS="~alpha ~amd64 ~arm64 ~hppa ~ppc ~ppc64 ~sparc ~x86"
+fi
+LICENSE="MIT"
+
+SLOT="0"
+IUSE="debug +gtk gtk2 ipv6 gssapi"
+
+RDEPEND="
+	!net-misc/pssh
+	gtk? (
+		dev-libs/glib:2
+		x11-libs/gdk-pixbuf
+		x11-libs/libX11
+		x11-libs/pango
+		gtk2? ( x11-libs/gtk+:2 )
+		!gtk2? ( x11-libs/gtk+:3[X] )
+	)
+	gssapi? ( virtual/krb5 )
+"
+DEPEND="
+	${RDEPEND}
+"
+BDEPEND="
+	dev-lang/perl
+	virtual/pkgconfig
+"
+#[[ ${PV} == *9999 ]] && BDEPEND+=" doc? ( app-doc/halibut )"
+
+REQUIRED_USE="
+	gtk2? ( gtk )
+"
+
+src_unpack() {
+	[[ ${PV} == *9999 ]] && git-r3_src_unpack
+	default
+}
+
+src_configure() {
+	cd "${S}"/unix || die
+	local mycmakeargs=(
+		-DPUTTY_DEBUG="$(usex debug)"
+		-DPUTTY_GSSAPI="$(usex gssapi DYNAMIC OFF)"
+		-DPUTTY_GTK_VERSION=$(usex gtk $(usex gtk2 2 3 ) '')
+		-DPUTTY_IPV6="$(usex ipv6)"
+	)
+	cmake_src_configure
+}
+
+src_install() {
+	cmake_src_install
+
+	doman "${BUILD_DIR}"/doc/*.1
+
+	#if use doc ; then
+	#	docinto html
+	#	dodoc "${BUILD_DIR}"/doc/html/*.html
+	#fi
+
+	if use gtk ; then
+		local i
+		for i in 16 22 24 32 48 64 128 256; do
+			newicon -s ${i} \
+				"${WORKDIR}"/${PN}-icons/${PN}-${i}.png \
+				${PN}.png
+		done
+
+		# install desktop file provided by Gustav Schaffter in #49577
+		make_desktop_entry ${PN} PuTTY ${PN} Network
+	fi
+}
+
+pkg_postinst() {
+	use gtk && xdg_icon_cache_update
+}
+
+pkg_postrm() {
+	use gtk && xdg_icon_cache_update
+}
-- 
cgit v1.2.3