From 590b9b7b03bf4651e099949e318755af7cfa81b8 Mon Sep 17 00:00:00 2001
From: V3n3RiX <venerix@redcorelinux.org>
Date: Sun, 1 Aug 2021 22:03:23 +0100
Subject: gentoo resync : 01.08.2021

---
 net-misc/plowshare/plowshare-2.1.6-r1.ebuild | 57 ++++++++++++++++++++++++++++
 1 file changed, 57 insertions(+)
 create mode 100644 net-misc/plowshare/plowshare-2.1.6-r1.ebuild

(limited to 'net-misc/plowshare/plowshare-2.1.6-r1.ebuild')

diff --git a/net-misc/plowshare/plowshare-2.1.6-r1.ebuild b/net-misc/plowshare/plowshare-2.1.6-r1.ebuild
new file mode 100644
index 000000000000..cacd5eb72e61
--- /dev/null
+++ b/net-misc/plowshare/plowshare-2.1.6-r1.ebuild
@@ -0,0 +1,57 @@
+# Copyright 1999-2021 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=7
+
+DESCRIPTION="Command-line downloader and uploader for file-sharing websites"
+HOMEPAGE="https://github.com/mcrapet/plowshare"
+SRC_URI="https://github.com/mcrapet/${PN}/archive/v${PV}.tar.gz -> ${P}.tar.gz"
+
+LICENSE="GPL-3"
+SLOT="0"
+KEYWORDS="~amd64 ~arm ~ppc ~x86"
+IUSE="+javascript view-captcha"
+
+RDEPEND="
+	>=app-shells/bash-4
+	|| ( app-text/recode ( dev-lang/perl dev-perl/HTML-Parser ) )
+	dev-vcs/git
+	net-misc/curl
+	sys-apps/util-linux
+	virtual/imagemagick-tools[tiff]
+	javascript? ( || ( dev-lang/spidermonkey:0 dev-java/rhino ) )
+	view-captcha? ( || ( media-gfx/aview media-libs/libcaca ) )"
+
+# NOTES:
+# javascript dep should be any javascript interpreter using /usr/bin/js
+
+src_prepare() {
+	# Fix doc install path
+	sed -i -e "/^DOCDIR/s|plowshare|${PF}|" Makefile || die "sed failed"
+
+	default
+}
+
+src_compile() {
+	# There is a Makefile but it's not compiling anything, let's not try.
+	:
+}
+
+src_test() {
+	# Disable tests because all of them need a working Internet connection.
+	:
+}
+
+src_install() {
+	emake DESTDIR="${D}" PREFIX="/usr" \
+		PLOWSHARE_FORCE_VERSION="${PV}" install
+}
+
+pkg_postinst() {
+	elog "plowshare is not delivered with modules by default anymore"
+	elog "Per-user modules can be installed/updated with the plowmod command"
+	if ! use javascript; then
+		ewarn "Without javascript you will not be able to use modules"
+		ewarn "requering a Javascript shell (/usr/bin/js)"
+	fi
+}
-- 
cgit v1.2.3