From 7c59acba5699c9c58090a7a738669669a7307023 Mon Sep 17 00:00:00 2001
From: V3n3RiX <venerix@redcorelinux.org>
Date: Sat, 21 Aug 2021 23:14:26 +0100
Subject: gentoo resync : 21.08.2021

---
 net-misc/oidentd/oidentd-3.0.0-r1.ebuild | 59 ++++++++++++++++++++++++++++++++
 1 file changed, 59 insertions(+)
 create mode 100644 net-misc/oidentd/oidentd-3.0.0-r1.ebuild

(limited to 'net-misc/oidentd/oidentd-3.0.0-r1.ebuild')

diff --git a/net-misc/oidentd/oidentd-3.0.0-r1.ebuild b/net-misc/oidentd/oidentd-3.0.0-r1.ebuild
new file mode 100644
index 000000000000..3c1eea07ecf3
--- /dev/null
+++ b/net-misc/oidentd/oidentd-3.0.0-r1.ebuild
@@ -0,0 +1,59 @@
+# Copyright 1999-2021 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=8
+
+inherit systemd
+
+DESCRIPTION="Another (RFC1413 compliant) ident daemon"
+HOMEPAGE="https://oidentd.janikrabe.com/"
+SRC_URI="https://files.janikrabe.com/pub/${PN}/releases/${PV}/${P}.tar.xz"
+
+LICENSE="BSD-2 GPL-2 LGPL-2+"
+SLOT="0"
+KEYWORDS="~alpha ~amd64 ~arm ~hppa ~ia64 ~mips ~ppc ~ppc64 ~s390 ~sparc ~x86"
+IUSE="debug ipv6 masquerade selinux"
+
+DEPEND="masquerade? ( net-libs/libnetfilter_conntrack )"
+
+RDEPEND="
+	${DEPEND}
+	acct-user/oidentd
+	acct-group/oidentd
+	selinux? ( sec-policy/selinux-oident )
+"
+
+BDEPEND="
+	sys-devel/bison
+	sys-devel/flex
+"
+
+PATCHES=( "${FILESDIR}/${P}-ipv6-masquerade.patch" )
+
+src_prepare() {
+	sed -i '/ExecStart/ s|$| -u oidentd -g oidentd|' contrib/systemd/*.service || die
+
+	default
+}
+
+src_configure() {
+	local myconf=(
+		$(use_enable debug)
+		$(use_enable ipv6)
+		$(use_enable masquerade libnfct)
+		$(use_enable masquerade nat)
+		--enable-xdgbdir
+	)
+	econf "${myconf[@]}"
+}
+
+src_install() {
+	default
+
+	newinitd "${FILESDIR}"/${PN}-2.0.7-init ${PN}
+	newconfd "${FILESDIR}"/${PN}-2.2.2-confd ${PN}
+
+	systemd_dounit contrib/systemd/${PN}@.service
+	systemd_dounit contrib/systemd/${PN}.socket
+	systemd_dounit contrib/systemd/${PN}.service
+}
-- 
cgit v1.2.3