From dbbd2ae5e62a232616ede4dae3ed69e15903940a Mon Sep 17 00:00:00 2001
From: V3n3RiX <venerix@koprulu.sector>
Date: Tue, 24 Jan 2023 18:57:53 +0000
Subject: gentoo auto-resync : 24:01:2023 - 18:57:53

---
 .../nextcloud-client-3.6.4-r3.ebuild               | 111 +++++++++++++++++++++
 1 file changed, 111 insertions(+)
 create mode 100644 net-misc/nextcloud-client/nextcloud-client-3.6.4-r3.ebuild

(limited to 'net-misc/nextcloud-client/nextcloud-client-3.6.4-r3.ebuild')

diff --git a/net-misc/nextcloud-client/nextcloud-client-3.6.4-r3.ebuild b/net-misc/nextcloud-client/nextcloud-client-3.6.4-r3.ebuild
new file mode 100644
index 000000000000..ff3700521620
--- /dev/null
+++ b/net-misc/nextcloud-client/nextcloud-client-3.6.4-r3.ebuild
@@ -0,0 +1,111 @@
+# Copyright 1999-2023 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=8
+
+inherit cmake virtualx xdg
+
+DESCRIPTION="Desktop Syncing Client for Nextcloud"
+HOMEPAGE="https://github.com/nextcloud/desktop"
+SRC_URI="https://github.com/nextcloud/desktop/archive/v${PV/_/-}.tar.gz -> ${P}.tar.gz"
+S="${WORKDIR}/desktop-${PV/_/-}"
+
+LICENSE="CC-BY-3.0 GPL-2"
+SLOT="0"
+KEYWORDS="~amd64 ~arm64 ~x86"
+IUSE="doc dolphin nautilus test webengine"
+RESTRICT="!test? ( test )"
+
+# slot op for qtqui as this package uses private API parts of qtqui
+# src/gui/generalsettings.cpp:#include <private/qzipwriter_p.h>
+RDEPEND="
+	>=dev-db/sqlite-3.34:3
+	>=dev-libs/openssl-1.1.0:0=
+	dev-libs/qtkeychain:=[qt5(+)]
+	dev-qt/qtcore:5
+	dev-qt/qtdbus:5
+	dev-qt/qtdeclarative:5
+	dev-qt/qtgui:5=
+	dev-qt/qtnetwork:5[ssl]
+	dev-qt/qtquickcontrols2:5
+	dev-qt/qtsvg:5
+	dev-qt/qtwebsockets:5
+	dev-qt/qtwidgets:5
+	net-libs/libcloudproviders
+	sys-libs/zlib
+	dolphin? (
+		kde-frameworks/kcoreaddons:5
+		kde-frameworks/kio:5
+	)
+	nautilus? ( dev-python/nautilus-python )
+	webengine? ( dev-qt/qtwebengine:5[widgets] )
+"
+DEPEND="
+	${R_DEPEND}
+	dev-qt/qtconcurrent:5
+	dev-qt/qtxml:5
+	|| ( gnome-base/librsvg media-gfx/inkscape )
+	doc? (
+		dev-python/sphinx
+		dev-tex/latexmk
+		dev-texlive/texlive-latexextra
+		virtual/latex-base
+	)
+	test? (
+		dev-qt/qttest:5
+		dev-util/cmocka
+	)
+"
+BDEPEND="
+	dev-qt/linguist-tools:5
+	dolphin? ( kde-frameworks/extra-cmake-modules )
+"
+
+PATCHES=(
+	# https://github.com/nextcloud/desktop/pull/5309
+	"${FILESDIR}"/${PN}-3.6.4-drop-dependency-on-Qt-Quick-Controls-1.patch
+)
+
+src_prepare() {
+	# Keep tests in ${T}
+	sed -i -e "s#\"/tmp#\"${T}#g" test/test*.cpp || die
+
+	cmake_src_prepare
+}
+
+src_configure() {
+	local mycmakeargs=(
+		-DCMAKE_INSTALL_DOCDIR=/usr/share/doc/${PF}
+		-DBUILD_UPDATER=OFF
+		$(cmake_use_find_package doc Sphinx)
+		$(cmake_use_find_package doc PdfLatex)
+		$(cmake_use_find_package webengine Qt5WebEngine)
+		$(cmake_use_find_package webengine Qt5WebEngineWidgets)
+		-DBUILD_SHELL_INTEGRATION_DOLPHIN=$(usex dolphin)
+		-DBUILD_SHELL_INTEGRATION_NAUTILUS=$(usex nautilus)
+		-DBUILD_TESTING=$(usex test)
+	)
+
+	cmake_src_configure
+}
+
+src_test() {
+	virtx cmake_src_test
+}
+
+src_compile() {
+	local compile_targets=(all)
+	if use doc; then
+		compile_targets+=(doc doc-man)
+	fi
+	cmake_src_compile ${compile_targets[@]}
+}
+
+pkg_postinst() {
+	xdg_pkg_postinst
+
+	if ! use doc ; then
+		elog "Documentation and man pages not installed"
+		elog "Enable doc USE-flag to generate them"
+	fi
+}
-- 
cgit v1.2.3