From de49812990871e1705b64051c35161d5e6400269 Mon Sep 17 00:00:00 2001
From: V3n3RiX <venerix@redcorelinux.org>
Date: Mon, 24 Dec 2018 14:11:38 +0000
Subject: gentoo resync : 24.12.2018

---
 net-misc/kea/kea-1.5.0.ebuild | 72 +++++++++++++++++++++++++++++++++++++++++++
 1 file changed, 72 insertions(+)
 create mode 100644 net-misc/kea/kea-1.5.0.ebuild

(limited to 'net-misc/kea/kea-1.5.0.ebuild')

diff --git a/net-misc/kea/kea-1.5.0.ebuild b/net-misc/kea/kea-1.5.0.ebuild
new file mode 100644
index 000000000000..75288a0c58a2
--- /dev/null
+++ b/net-misc/kea/kea-1.5.0.ebuild
@@ -0,0 +1,72 @@
+# Copyright 1999-2018 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=6
+
+inherit toolchain-funcs user
+
+MY_PV="${PV//_p/-P}"
+MY_PV="${MY_PV/_/-}"
+MY_P="${PN}-${MY_PV}"
+
+DESCRIPTION="High-performance production grade DHCPv4 & DHCPv6 server"
+HOMEPAGE="http://www.isc.org/kea/"
+if [[ ${PV} = 9999* ]] ; then
+	inherit autotools git-r3
+	EGIT_REPO_URI="https://github.com/isc-projects/kea.git"
+else
+	SRC_URI="ftp://ftp.isc.org/isc/kea/${MY_P}.tar.gz
+		ftp://ftp.isc.org/isc/kea/${MY_PV}/${MY_P}.tar.gz"
+	[[ "${PV}" == *_beta* ]] || [[ "${PV}" == *_rc* ]] || \
+	KEYWORDS="~amd64 ~x86"
+fi
+
+LICENSE="ISC BSD SSLeay GPL-2" # GPL-2 only for init script
+SLOT="0"
+IUSE="mysql openssl postgres samples"
+
+DEPEND="
+	dev-libs/boost:=
+	dev-cpp/gtest
+	dev-libs/log4cplus
+	mysql? ( dev-db/mysql-connector-c )
+	!openssl? ( dev-libs/botan:0= )
+	openssl? ( dev-libs/openssl:0= )
+	postgres? ( dev-db/postgresql:* )
+"
+RDEPEND="${DEPEND}"
+
+S="${WORKDIR}/${MY_P}"
+
+src_prepare() {
+	default
+	[[ ${PV} = *9999 ]] && eautoreconf
+	# Brand the version with Gentoo
+	sed -i \
+		-e "/VERSION=/s:'$: Gentoo-${PR}':" \
+		configure || die
+}
+
+src_configure() {
+	local myeconfargs=(
+		$(use_with mysql)
+		$(use_with openssl)
+		$(use_with postgres pgsql)
+		$(use_enable samples install-configurations)
+		--disable-static
+		--without-werror
+	)
+	econf "${myeconfargs[@]}"
+}
+
+src_install() {
+	default
+	newconfd "${FILESDIR}"/${PN}-confd ${PN}
+	newinitd "${FILESDIR}"/${PN}-initd ${PN}
+	find "${ED}" \( -name "*.a" -o -name "*.la" \) -delete || die
+}
+
+pkg_preinst() {
+	enewgroup dhcp
+	enewuser dhcp -1 -1 /var/lib/dhcp dhcp
+}
-- 
cgit v1.2.3