From b1c81de4fadbd00897700a7321f03b390d952b2e Mon Sep 17 00:00:00 2001
From: V3n3RiX <venerix@redcorelinux.org>
Date: Thu, 26 Aug 2021 00:09:36 +0100
Subject: gentoo resync : 26.08.2021

---
 net-mail/vqadmin/vqadmin-2.3.7-r1.ebuild | 62 ++++++++++++++++++++++++++++++++
 1 file changed, 62 insertions(+)
 create mode 100644 net-mail/vqadmin/vqadmin-2.3.7-r1.ebuild

(limited to 'net-mail/vqadmin/vqadmin-2.3.7-r1.ebuild')

diff --git a/net-mail/vqadmin/vqadmin-2.3.7-r1.ebuild b/net-mail/vqadmin/vqadmin-2.3.7-r1.ebuild
new file mode 100644
index 000000000000..a89f49b9d5c3
--- /dev/null
+++ b/net-mail/vqadmin/vqadmin-2.3.7-r1.ebuild
@@ -0,0 +1,62 @@
+# Copyright 1999-2021 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=7
+
+inherit webapp autotools qmail
+
+DESCRIPTION="A web based control pannel to manage Virtual Qmail Domains"
+HOMEPAGE="http://www.inter7.com/index.php?page=vqadmin"
+SRC_URI="http://www.inter7.com/vqadmin/${P}.tar.gz"
+
+LICENSE="GPL-2"
+SLOT="0"
+WEBAPP_MANUAL_SLOT="yes"
+KEYWORDS="~amd64 ~ppc ~sparc ~x86"
+IUSE=""
+
+DEPEND="virtual/libcrypt:=
+	virtual/qmail
+	>=net-mail/vpopmail-5.3"
+RDEPEND="${DEPEND}
+	net-mail/qmailadmin"
+
+src_prepare() {
+	default
+
+	# fixes for sane webapp integration
+	sed -i \
+		-e "s|html/|/usr/share/${PN}/|g" \
+		-e "s|/images/vqadmin/|/vqadmin/|g" \
+		-e "s|/cgi-bin/vqadmin/|/cgi-bin/|g" \
+		-e "s|vqadmin\.cgi|vqadmin|g" \
+		*.h *.c html/*.html || die
+}
+
+src_configure() {
+	econf \
+		--enable-qmaildir="${QMAIL_HOME}" \
+		--enable-vpopuser=vpopmail \
+		--enable-vpopgroup=vpopmail \
+		--enable-cgibindir="${MY_CGIBINDIR}"
+}
+
+src_install() {
+	webapp_src_preinst
+
+	insinto /usr/share/${PN}
+	doins html/*
+
+	insinto "${MY_HTDOCSDIR}"
+	doins html/*.css
+
+	insinto "${MY_CGIBINDIR}"
+	doins vqadmin.acl
+	insopts -m 755
+	doins vqadmin
+
+	dodoc ACL AUTHORS BUGS ChangeLog FAQ INSTALL NEWS TODO README
+
+	webapp_postinst_txt en "${FILESDIR}"/postinstall-en.txt
+	webapp_src_install
+}
-- 
cgit v1.2.3