From 4f2d7949f03e1c198bc888f2d05f421d35c57e21 Mon Sep 17 00:00:00 2001
From: V3n3RiX <venerix@redcorelinux.org>
Date: Mon, 9 Oct 2017 18:53:29 +0100
Subject: reinit the tree, so we can have metadata

---
 net-libs/zeromq/zeromq-4.1.6.ebuild | 55 +++++++++++++++++++++++++++++++++++++
 1 file changed, 55 insertions(+)
 create mode 100644 net-libs/zeromq/zeromq-4.1.6.ebuild

(limited to 'net-libs/zeromq/zeromq-4.1.6.ebuild')

diff --git a/net-libs/zeromq/zeromq-4.1.6.ebuild b/net-libs/zeromq/zeromq-4.1.6.ebuild
new file mode 100644
index 000000000000..ffa1660ff95d
--- /dev/null
+++ b/net-libs/zeromq/zeromq-4.1.6.ebuild
@@ -0,0 +1,55 @@
+# Copyright 1999-2017 Gentoo Foundation
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=6
+
+inherit autotools eutils
+
+DESCRIPTION="A brokerless kernel"
+HOMEPAGE="http://www.zeromq.org/"
+SRC_URI="https://github.com/zeromq/zeromq4-1/releases/download/v${PV}/${P}.tar.gz"
+
+LICENSE="LGPL-3"
+SLOT="0/5"
+KEYWORDS="amd64 arm ~arm64 hppa ia64 ~mips ppc ppc64 x86 ~amd64-linux ~x86-linux"
+IUSE="pgm static-libs test"
+
+RDEPEND="
+	dev-libs/libsodium:=
+	pgm? ( =net-libs/openpgm-5.2.122 )"
+DEPEND="${RDEPEND}
+	app-text/asciidoc
+	app-text/xmlto
+	sys-apps/util-linux
+	pgm? ( virtual/pkgconfig )"
+
+src_prepare() {
+	sed \
+		-e '/libzmq_werror=/s:yes:no:g' \
+		-i configure.ac || die
+	default
+	eautoreconf
+}
+
+src_configure() {
+	local myeconfargs=(
+		--enable-shared
+		$(use_enable static-libs static)
+		--with-relaxed
+		--with-libsodium
+		$(use_with pgm)
+	)
+	econf "${myeconfargs[@]}"
+}
+
+src_test() {
+	# Restricting to one job because multiple tests are using the same port.
+	# Upstream knows the problem and says it doesn't support parallel test
+	# execution, see ${S}/INSTALL.
+	emake -j1 check
+}
+
+src_install() {
+	default
+	prune_libtool_files
+}
-- 
cgit v1.2.3