From 5bb9ff1ee56d2b5e75e01a7f066d8b0cec84ec02 Mon Sep 17 00:00:00 2001
From: V3n3RiX <venerix@redcorelinux.org>
Date: Sat, 20 Mar 2021 14:27:17 +0000
Subject: gentoo resync : 20.03.2021

---
 .../telepathy-glib/telepathy-glib-0.24.2.ebuild    | 66 ++++++++++++++++++++++
 1 file changed, 66 insertions(+)
 create mode 100644 net-libs/telepathy-glib/telepathy-glib-0.24.2.ebuild

(limited to 'net-libs/telepathy-glib/telepathy-glib-0.24.2.ebuild')

diff --git a/net-libs/telepathy-glib/telepathy-glib-0.24.2.ebuild b/net-libs/telepathy-glib/telepathy-glib-0.24.2.ebuild
new file mode 100644
index 000000000000..3d51fb532d10
--- /dev/null
+++ b/net-libs/telepathy-glib/telepathy-glib-0.24.2.ebuild
@@ -0,0 +1,66 @@
+# Copyright 1999-2021 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=7
+
+PYTHON_COMPAT=( python3_{7..9} )
+VALA_MIN_API_VERSION="0.18"
+VALA_USE_DEPEND="vapigen"
+
+inherit gnome2 python-any-r1 vala virtualx
+
+DESCRIPTION="GLib bindings for the Telepathy D-Bus protocol"
+HOMEPAGE="https://telepathy.freedesktop.org/"
+SRC_URI="https://telepathy.freedesktop.org/releases/${PN}/${P}.tar.gz"
+
+LICENSE="LGPL-2.1+"
+SLOT="0"
+KEYWORDS="~alpha ~amd64 ~arm ~arm64 ~ia64 ~ppc ~ppc64 ~sparc ~x86 ~amd64-linux ~x86-linux"
+
+IUSE="debug +introspection +vala"
+REQUIRED_USE="vala? ( introspection )"
+
+# Broken for a long time and upstream doesn't care
+# https://bugs.freedesktop.org/show_bug.cgi?id=63212
+RESTRICT="test"
+
+RDEPEND="
+	>=dev-libs/glib-2.36:2
+	>=dev-libs/dbus-glib-0.90
+	introspection? ( >=dev-libs/gobject-introspection-1.30 )
+"
+DEPEND="${RDEPEND}
+	vala? ( $(vala_depend) )
+"
+BDEPEND="
+	${PYTHON_DEPS}
+	dev-libs/libxslt
+	dev-util/glib-utils
+	dev-util/gtk-doc-am
+	virtual/pkgconfig
+"
+# See bug 504744 for reference
+PDEPEND="
+	net-im/telepathy-mission-control
+"
+
+src_prepare() {
+	use vala && vala_src_prepare
+	gnome2_src_prepare
+}
+
+src_configure() {
+	gnome2_src_configure \
+		--disable-static \
+		--disable-installed-tests \
+		$(use_enable debug backtrace) \
+		$(use_enable debug debug-cache) \
+		$(use_enable introspection) \
+		$(use_enable vala vala-bindings)
+}
+
+src_test() {
+	unset DBUS_SESSION_BUS_ADDRESS
+	# Needs dbus for tests (auto-launched)
+	virtx emake -j1 check
+}
-- 
cgit v1.2.3