From eedf7b9dec39b69b43f7b581da418d37428db449 Mon Sep 17 00:00:00 2001
From: V3n3RiX <venerix@koprulu.sector>
Date: Sat, 20 May 2023 22:19:27 +0100
Subject: gentoo auto-resync : 20:05:2023 - 22:19:26

---
 net-libs/qxmpp/qxmpp-1.5.5.ebuild | 57 +++++++++++++++++++++++++++++++++++++++
 1 file changed, 57 insertions(+)
 create mode 100644 net-libs/qxmpp/qxmpp-1.5.5.ebuild

(limited to 'net-libs/qxmpp/qxmpp-1.5.5.ebuild')

diff --git a/net-libs/qxmpp/qxmpp-1.5.5.ebuild b/net-libs/qxmpp/qxmpp-1.5.5.ebuild
new file mode 100644
index 000000000000..8f2dfc6cee67
--- /dev/null
+++ b/net-libs/qxmpp/qxmpp-1.5.5.ebuild
@@ -0,0 +1,57 @@
+# Copyright 1999-2023 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=8
+
+inherit cmake
+
+DESCRIPTION="A cross-platform C++ XMPP client library based on the Qt framework"
+HOMEPAGE="https://github.com/qxmpp-project/qxmpp"
+SRC_URI="https://github.com/${PN}-project/${PN}/archive/v${PV}.tar.gz -> ${P}.tar.gz"
+
+LICENSE="LGPL-2.1"
+SLOT="0"
+KEYWORDS="~amd64 ~x86"
+IUSE="doc gstreamer omemo test"
+RESTRICT="!test? ( test )"
+
+RDEPEND="
+	dev-qt/qtcore:5
+	dev-qt/qtnetwork:5[ssl]
+	dev-qt/qtxml:5
+	gstreamer? ( media-libs/gstreamer )
+	omemo? (
+		app-crypt/qca:2[qt5(+)]
+		net-libs/libomemo-c
+	)
+"
+DEPEND="${RDEPEND}
+	test? ( dev-qt/qttest:5 )
+"
+BDEPEND="
+	doc? ( app-doc/doxygen )
+"
+
+src_configure() {
+	local mycmakeargs=(
+		-DBUILD_DOCUMENTATION=$(usex doc)
+		-DBUILD_EXAMPLES=OFF
+		-DBUILD_TESTS=$(usex test)
+		-DBUILD_INTERNAL_TESTS=$(usex test)
+		-DBUILD_OMEMO=$(usex omemo)
+		-DWITH_QCA=$(usex omemo)
+		-DWITH_GSTREAMER=$(usex gstreamer)
+		-DQT_VERSION_MAJOR=5
+	)
+
+	cmake_src_configure
+}
+
+src_test() {
+	local myctestargs=(
+		# require network connection, bug #623708
+		-E "tst_(qxmpptransfermanager|qxmppiceconnection)"
+	)
+
+	cmake_src_test
+}
-- 
cgit v1.2.3