From 4f2d7949f03e1c198bc888f2d05f421d35c57e21 Mon Sep 17 00:00:00 2001
From: V3n3RiX <venerix@redcorelinux.org>
Date: Mon, 9 Oct 2017 18:53:29 +0100
Subject: reinit the tree, so we can have metadata

---
 net-libs/ortp/ortp-0.23.0-r1.ebuild | 78 +++++++++++++++++++++++++++++++++++++
 1 file changed, 78 insertions(+)
 create mode 100644 net-libs/ortp/ortp-0.23.0-r1.ebuild

(limited to 'net-libs/ortp/ortp-0.23.0-r1.ebuild')

diff --git a/net-libs/ortp/ortp-0.23.0-r1.ebuild b/net-libs/ortp/ortp-0.23.0-r1.ebuild
new file mode 100644
index 000000000000..f9f6a6b1384f
--- /dev/null
+++ b/net-libs/ortp/ortp-0.23.0-r1.ebuild
@@ -0,0 +1,78 @@
+# Copyright 1999-2016 Gentoo Foundation
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=6
+inherit eutils
+
+DESCRIPTION="Open Real-time Transport Protocol (RTP, RFC3550) stack"
+HOMEPAGE="http://www.linphone.org/"
+SRC_URI="mirror://nongnu/linphone/${PN}/sources/${P}.tar.gz"
+
+LICENSE="LGPL-2.1"
+SLOT="0/9"
+KEYWORDS="alpha amd64 ia64 ppc ppc64 sparc x86 ~x86-fbsd ~ppc-macos ~x64-macos ~x86-macos"
+IUSE="debug doc examples ipv6 libressl minimal ntp-timestamp ssl srtp"
+
+RDEPEND="
+	ssl? (
+		!libressl? ( dev-libs/openssl:0= )
+		libressl? ( dev-libs/libressl:= ) )
+	srtp? ( net-libs/libsrtp:0= )
+"
+DEPEND="${RDEPEND}
+	doc? ( app-doc/doxygen )
+	virtual/pkgconfig
+"
+
+src_prepare() {
+	default
+	# ${P} is added after ${docdir}
+	if use doc; then
+		sed -i -e 's/$(docdir)\/$(PACKAGE)-$(VERSION)/$(docdir)/' Makefile.in \
+			|| die "patching Makefile.in failed"
+	fi
+}
+
+src_configure() {
+	local myeconfargs=(
+		# memcheck is for HP-UX only
+		--disable-memcheck
+		# mode64bit adds +DA2.0W +DS2.0 CFLAGS wich are needed for HP-UX
+		--disable-mode64bit
+		# strict adds -Werror, do not want it
+		--disable-strict
+		# they seriously failed to understand AC_ARG_ENABLE...
+		--disable-tests_enabled
+		--enable-fast-install
+		--enable-libtool-lock
+		# this is fine as long as we do not link to polarssl
+		--enable-broken-srtp
+		# zrtp removed from the tree
+		--disable-zrtp
+
+		$(use_enable debug)
+		$(use_enable ipv6)
+		$(use_enable minimal perf)
+		$(use_enable ntp-timestamp)
+		$(use_enable ssl ssl-hmac)
+
+		--with-srtp=$(usex srtp "${EPREFIX}"/usr none)
+		$(use doc || echo ac_cv_path_DOXYGEN=false)
+	)
+
+	econf "${myeconfargs[@]}"
+}
+
+src_install() {
+	emake DESTDIR="${D}" pkgdocdir="${EPREFIX}"/usr/share/doc/${PF} \
+		install
+
+	einstalldocs
+
+	prune_libtool_files
+
+	if use examples; then
+		insinto /usr/share/doc/${PF}/examples
+		doins src/tests/*.c
+	fi
+}
-- 
cgit v1.2.3