From 3f71901f8c228f4de570abed1831ce3ee425343e Mon Sep 17 00:00:00 2001
From: V3n3RiX <venerix@redcorelinux.org>
Date: Sat, 8 Sep 2018 10:50:14 +0100
Subject: gentoo resync 08.09.2018

---
 net-libs/nghttp2/nghttp2-1.33.0.ebuild | 68 ++++++++++++++++++++++++++++++++++
 1 file changed, 68 insertions(+)
 create mode 100644 net-libs/nghttp2/nghttp2-1.33.0.ebuild

(limited to 'net-libs/nghttp2/nghttp2-1.33.0.ebuild')

diff --git a/net-libs/nghttp2/nghttp2-1.33.0.ebuild b/net-libs/nghttp2/nghttp2-1.33.0.ebuild
new file mode 100644
index 000000000000..b8cb21f53b53
--- /dev/null
+++ b/net-libs/nghttp2/nghttp2-1.33.0.ebuild
@@ -0,0 +1,68 @@
+# Copyright 1999-2018 Gentoo Foundation
+# Distributed under the terms of the GNU General Public License v2
+
+# TODO: Add python support.
+
+EAPI=7
+
+inherit multilib-minimal
+
+if [[ ${PV} == 9999 ]] ; then
+	EGIT_REPO_URI="https://github.com/nghttp2/nghttp2.git"
+	inherit git-r3
+else
+	SRC_URI="https://github.com/nghttp2/nghttp2/releases/download/v${PV}/${P}.tar.xz"
+	KEYWORDS="~alpha ~amd64 ~arm ~arm64 ~hppa ~ia64 ~m68k ~mips ~ppc ~ppc64 ~s390 ~sh ~sparc ~x86 ~amd64-fbsd"
+fi
+
+DESCRIPTION="HTTP/2 C Library"
+HOMEPAGE="https://nghttp2.org/"
+
+LICENSE="MIT"
+SLOT="0/1.14" # <C++>.<C> SONAMEs
+IUSE="cxx debug hpack-tools jemalloc libressl static-libs test +threads utils xml"
+
+SSL_DEPEND="
+	!libressl? ( >=dev-libs/openssl-1.0.2:0=[-bindist,${MULTILIB_USEDEP}] )
+	libressl? ( dev-libs/libressl:=[${MULTILIB_USEDEP}] )
+"
+RDEPEND="
+	cxx? (
+		${SSL_DEPEND}
+		dev-libs/boost:=[${MULTILIB_USEDEP},threads]
+	)
+	hpack-tools? ( >=dev-libs/jansson-2.5 )
+	jemalloc? ( dev-libs/jemalloc[${MULTILIB_USEDEP}] )
+	utils? (
+		${SSL_DEPEND}
+		>=dev-libs/libev-4.15[${MULTILIB_USEDEP}]
+		>=sys-libs/zlib-1.2.3[${MULTILIB_USEDEP}]
+		net-dns/c-ares:=[${MULTILIB_USEDEP}]
+	)
+	xml? ( >=dev-libs/libxml2-2.7.7:2[${MULTILIB_USEDEP}] )"
+DEPEND="${RDEPEND}
+	virtual/pkgconfig
+	test? ( >=dev-util/cunit-2.1[${MULTILIB_USEDEP}] )"
+
+multilib_src_configure() {
+	local myeconfargs=(
+		--disable-examples
+		--disable-failmalloc
+		--disable-werror
+		--without-cython
+		--disable-python-bindings
+		$(use_enable cxx asio-lib)
+		$(use_enable debug)
+		$(multilib_native_use_enable hpack-tools)
+		$(use_enable static-libs static)
+		$(use_enable threads)
+		$(multilib_native_use_enable utils app)
+		$(multilib_native_use_with jemalloc)
+		$(multilib_native_use_with xml libxml2)
+	)
+	ECONF_SOURCE="${S}" econf "${myeconfargs[@]}"
+}
+
+multilib_src_install_all() {
+	use static-libs || find "${ED%/}"/usr -name '*.la' -delete
+}
-- 
cgit v1.2.3