From 3b08f674e3f771b49370edb144dab0958c8cf721 Mon Sep 17 00:00:00 2001
From: V3n3RiX <venerix@redcorelinux.org>
Date: Tue, 31 Aug 2021 08:59:54 +0100
Subject: gentoo resync : 31.08.2021

---
 net-libs/libssh2/libssh2-1.10.0.ebuild | 53 ++++++++++++++++++++++++++++++++++
 1 file changed, 53 insertions(+)
 create mode 100644 net-libs/libssh2/libssh2-1.10.0.ebuild

(limited to 'net-libs/libssh2/libssh2-1.10.0.ebuild')

diff --git a/net-libs/libssh2/libssh2-1.10.0.ebuild b/net-libs/libssh2/libssh2-1.10.0.ebuild
new file mode 100644
index 000000000000..309a9aac8403
--- /dev/null
+++ b/net-libs/libssh2/libssh2-1.10.0.ebuild
@@ -0,0 +1,53 @@
+# Copyright 1999-2021 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=7
+CMAKE_ECLASS=cmake
+inherit cmake-multilib
+
+DESCRIPTION="Library implementing the SSH2 protocol"
+HOMEPAGE="https://www.libssh2.org"
+SRC_URI="https://www.libssh2.org/download/${P}.tar.gz"
+
+LICENSE="BSD"
+SLOT="0"
+KEYWORDS="~alpha ~amd64 ~arm ~arm64 ~hppa ~ia64 ~mips ~ppc ~ppc64 ~riscv ~s390 ~sparc ~x86 ~amd64-linux ~x86-linux ~ppc-macos ~x64-macos ~x86-solaris"
+IUSE="gcrypt mbedtls zlib"
+REQUIRED_USE="?? ( gcrypt mbedtls )"
+# Tests try to set containers up using docker (and fail for some reason).
+RESTRICT="test"
+
+RDEPEND="
+	gcrypt? ( >=dev-libs/libgcrypt-1.5.3:0[${MULTILIB_USEDEP}] )
+	!gcrypt? (
+		mbedtls? ( net-libs/mbedtls:0=[${MULTILIB_USEDEP}] )
+		!mbedtls? (
+			>=dev-libs/openssl-1.0.1h-r2:0=[${MULTILIB_USEDEP}]
+		)
+	)
+	zlib? ( >=sys-libs/zlib-1.2.8-r1[${MULTILIB_USEDEP}] )
+"
+DEPEND="
+	${RDEPEND}
+"
+
+multilib_src_configure() {
+	local crypto_backend=OpenSSL
+	if use gcrypt; then
+		crypto_backend=Libgcrypt
+	elif use mbedtls; then
+		crypto_backend=mbedTLS
+	fi
+
+	local mycmakeargs=(
+		-DBUILD_SHARED_LIBS=ON
+		-DCRYPTO_BACKEND=${crypto_backend}
+		-DENABLE_ZLIB_COMPRESSION=$(usex zlib)
+	)
+	cmake_src_configure
+}
+
+multilib_src_install_all() {
+	einstalldocs
+	find "${ED}" -name '*.la' -delete || die
+}
-- 
cgit v1.2.3