From 4f2d7949f03e1c198bc888f2d05f421d35c57e21 Mon Sep 17 00:00:00 2001
From: V3n3RiX <venerix@redcorelinux.org>
Date: Mon, 9 Oct 2017 18:53:29 +0100
Subject: reinit the tree, so we can have metadata

---
 net-libs/libqmi/libqmi-9999.ebuild | 45 ++++++++++++++++++++++++++++++++++++++
 1 file changed, 45 insertions(+)
 create mode 100644 net-libs/libqmi/libqmi-9999.ebuild

(limited to 'net-libs/libqmi/libqmi-9999.ebuild')

diff --git a/net-libs/libqmi/libqmi-9999.ebuild b/net-libs/libqmi/libqmi-9999.ebuild
new file mode 100644
index 000000000000..1508e965a7e2
--- /dev/null
+++ b/net-libs/libqmi/libqmi-9999.ebuild
@@ -0,0 +1,45 @@
+# Copyright 1999-2017 Gentoo Foundation
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI="6"
+
+inherit multilib
+if [[ ${PV} == "9999" ]] ; then
+	inherit git-r3 autotools
+	EGIT_REPO_URI="https://anongit.freedesktop.org/git/libqmi.git"
+else
+	KEYWORDS="~amd64 ~arm ~arm64 ~mips ~x86"
+	SRC_URI="https://www.freedesktop.org/software/libqmi/${P}.tar.xz"
+fi
+
+DESCRIPTION="Qualcomm MSM (Mobile Station Modem) Interface (QMI) modem protocol helper library"
+HOMEPAGE="https://cgit.freedesktop.org/libqmi/"
+
+LICENSE="LGPL-2"
+SLOT="0/5.1"	# soname of libqmi-glib.so
+IUSE="doc +mbim static-libs"
+
+RDEPEND=">=dev-libs/glib-2.36
+	mbim? ( >=net-libs/libmbim-1.14.0 )"
+DEPEND="${RDEPEND}
+	doc? ( dev-util/gtk-doc )
+	virtual/pkgconfig"
+[[ ${PV} == "9999" ]] && DEPEND+=" dev-util/gtk-doc" #469214
+
+src_prepare() {
+	default
+	[[ -e configure ]] || eautoreconf
+}
+
+src_configure() {
+	econf \
+		--disable-more-warnings \
+		$(use_enable mbim mbim-qmux) \
+		$(use_enable static{-libs,}) \
+		$(use_enable {,gtk-}doc)
+}
+
+src_install() {
+	default
+	use static-libs || rm -f "${ED}/usr/$(get_libdir)/${PN}-glib.la"
+}
-- 
cgit v1.2.3