From c4507bfdfd706b2b1301972490fe88ac3ddbc70e Mon Sep 17 00:00:00 2001
From: V3n3RiX <venerix@koprulu.sector>
Date: Tue, 16 May 2023 22:07:44 +0100
Subject: gentoo auto-resync : 16:05:2023 - 22:07:44

---
 net-libs/libproxy/libproxy-0.5.0.ebuild | 77 +++++++++++++++++++++++++++++++++
 1 file changed, 77 insertions(+)
 create mode 100644 net-libs/libproxy/libproxy-0.5.0.ebuild

(limited to 'net-libs/libproxy/libproxy-0.5.0.ebuild')

diff --git a/net-libs/libproxy/libproxy-0.5.0.ebuild b/net-libs/libproxy/libproxy-0.5.0.ebuild
new file mode 100644
index 000000000000..19c04bc6750a
--- /dev/null
+++ b/net-libs/libproxy/libproxy-0.5.0.ebuild
@@ -0,0 +1,77 @@
+# Copyright 1999-2023 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=8
+
+inherit meson-multilib vala
+
+DESCRIPTION="Library for automatic proxy configuration management"
+HOMEPAGE="https://github.com/libproxy/libproxy"
+SRC_URI="https://github.com/libproxy/libproxy/archive/refs/tags/${P}.tar.gz"
+
+LICENSE="LGPL-2.1+"
+SLOT="0"
+KEYWORDS="~alpha ~amd64 ~arm ~arm64 ~hppa ~ia64 ~loong ~mips ~ppc ~ppc64 ~riscv ~sparc ~x86 ~amd64-linux ~x86-linux"
+IUSE="duktape gnome gtk-doc +introspection kde test vala"
+REQUIRED_USE="
+	gtk-doc? ( introspection )
+	vala? ( introspection )
+"
+RESTRICT="!test? ( test )"
+
+COMMON_DEPEND="
+	>=dev-libs/glib-2.71.3:2[${MULTILIB_USEDEP}]
+	gnome? ( gnome-base/gsettings-desktop-schemas )
+	duktape? (
+		dev-lang/duktape:=
+		net-misc/curl
+	)
+"
+DEPEND="${COMMON_DEPEND}
+	test? ( net-libs/libsoup:3.0[${MULTILIB_USEDEP}] )
+"
+RDEPEND="${COMMON_DEPEND}
+	kde? ( kde-frameworks/kconfig:5 )
+"
+BDEPEND="
+	virtual/pkgconfig
+	vala? ( $(vala_depend) )
+"
+
+S="${WORKDIR}/${PN}-${P}"
+
+PATCHES=(
+	"${FILESDIR}"/${PV}-Guard-PxManager-test-with-pacrunner-duktape-option-2.patch
+)
+
+src_prepare() {
+	use vala && vala_setup
+	default
+}
+
+multilib_src_configure() {
+	local emesonargs=(
+		$(meson_native_use_bool gtk-doc docs)
+		$(meson_use test tests)
+		-Dconfig-env=true
+		$(meson_use gnome config-gnome)
+		-Dconfig-windows=false
+		-Dconfig-sysconfig=true
+		-Dconfig-osx=false
+		$(meson_use kde config-kde)
+		$(meson_native_use_bool duktape pacrunner-duktape)
+		$(meson_native_use_bool vala vapi)
+		$(meson_use duktape curl)
+		$(meson_native_use_bool introspection)
+	)
+	meson_src_configure
+}
+
+multilib_src_install_all() {
+	einstalldocs
+
+	if use gtk-doc; then
+		mkdir -p "${ED}"/usr/share/gtk-doc/html/ || die
+		mv "${ED}"/usr/share/doc/${PN}-1.0 "${ED}"/usr/share/gtk-doc/html/ || die
+	fi
+}
-- 
cgit v1.2.3