From 032a3dbb5d4ea63ec6c2ceb39c067ea6424b5792 Mon Sep 17 00:00:00 2001
From: V3n3RiX <venerix@redcorelinux.org>
Date: Mon, 20 Jan 2020 19:28:42 +0000
Subject: gentoo resync : 20.01.2020

---
 net-libs/libpcap/libpcap-1.9.1-r3.ebuild | 82 ++++++++++++++++++++++++++++++++
 1 file changed, 82 insertions(+)
 create mode 100644 net-libs/libpcap/libpcap-1.9.1-r3.ebuild

(limited to 'net-libs/libpcap/libpcap-1.9.1-r3.ebuild')

diff --git a/net-libs/libpcap/libpcap-1.9.1-r3.ebuild b/net-libs/libpcap/libpcap-1.9.1-r3.ebuild
new file mode 100644
index 000000000000..9628a24a510e
--- /dev/null
+++ b/net-libs/libpcap/libpcap-1.9.1-r3.ebuild
@@ -0,0 +1,82 @@
+# Copyright 1999-2020 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=7
+inherit autotools multilib-minimal
+
+DESCRIPTION="A system-independent library for user-level network packet capture"
+HOMEPAGE="
+	https://www.tcpdump.org/
+	https://github.com/the-tcpdump-group/libpcap
+"
+SRC_URI="
+	https://github.com/the-tcpdump-group/${PN}/archive/${P/_}.tar.gz
+"
+
+LICENSE="BSD"
+SLOT="0"
+KEYWORDS="~amd64 ~hppa ~x86 ~amd64-linux ~x86-linux ~ppc-macos ~x64-macos ~x86-macos ~sparc-solaris ~x86-solaris"
+IUSE="bluetooth dbus netlink rdma -remote static-libs usb -yydebug"
+
+RDEPEND="
+	bluetooth? ( net-wireless/bluez:=[${MULTILIB_USEDEP}] )
+	dbus? ( sys-apps/dbus[${MULTILIB_USEDEP}] )
+	netlink? ( dev-libs/libnl:3[${MULTILIB_USEDEP}] )
+	rdma? ( sys-cluster/rdma-core )
+	usb? ( virtual/libusb:1[${MULTILIB_USEDEP}] )
+"
+DEPEND="
+	${RDEPEND}
+	sys-devel/flex
+	virtual/yacc
+	dbus? ( virtual/pkgconfig[${MULTILIB_USEDEP}] )
+"
+
+S=${WORKDIR}/${PN}-${P/_}
+
+PATCHES=(
+	"${FILESDIR}"/${PN}-1.8.1-usbmon.patch
+	"${FILESDIR}"/${PN}-1.9.1-pcap-config.patch
+)
+
+src_prepare() {
+	default
+
+	echo ${PV} > VERSION || die
+
+	eautoreconf
+}
+
+multilib_src_configure() {
+	ECONF_SOURCE="${S}" \
+	econf \
+		$(use_enable bluetooth) \
+		$(use_enable dbus) \
+		$(use_enable rdma) \
+		$(use_enable remote) \
+		$(use_enable usb) \
+		$(use_enable yydebug) \
+		$(use_with netlink libnl) \
+		--enable-ipv6
+}
+
+multilib_src_compile() {
+	emake all shared
+}
+
+multilib_src_install_all() {
+	dodoc CREDITS CHANGES VERSION TODO README.* doc/README.*
+
+	# remove static libraries (--disable-static does not work)
+	if ! use static-libs; then
+		find "${ED}" -name '*.a' -exec rm {} + || die
+	fi
+
+	find "${ED}" -name '*.la' -delete || die
+
+	# We need this to build pppd on G/FBSD systems
+	if [[ "${USERLAND}" == "BSD" ]]; then
+		insinto /usr/include
+		doins pcap-int.h portability.h
+	fi
+}
-- 
cgit v1.2.3