From 46eedbedafdb0040c37884982d4c775ce277fb7b Mon Sep 17 00:00:00 2001
From: V3n3RiX <venerix@koprulu.sector>
Date: Wed, 20 Oct 2021 10:22:14 +0100
Subject: gentoo resync : 20.10.2021

---
 net-libs/libnids/libnids-1.24-r8.ebuild | 58 +++++++++++++++++++++++++++++++++
 1 file changed, 58 insertions(+)
 create mode 100644 net-libs/libnids/libnids-1.24-r8.ebuild

(limited to 'net-libs/libnids/libnids-1.24-r8.ebuild')

diff --git a/net-libs/libnids/libnids-1.24-r8.ebuild b/net-libs/libnids/libnids-1.24-r8.ebuild
new file mode 100644
index 000000000000..a993c8d91295
--- /dev/null
+++ b/net-libs/libnids/libnids-1.24-r8.ebuild
@@ -0,0 +1,58 @@
+# Copyright 1999-2021 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=7
+
+inherit autotools flag-o-matic toolchain-funcs
+
+DESCRIPTION="an implementation of an E-component of Network Intrusion Detection System"
+HOMEPAGE="http://libnids.sourceforge.net/"
+SRC_URI="mirror://sourceforge/${PN}/${P}.tar.gz"
+
+LICENSE="GPL-2"
+SLOT="1.2"
+KEYWORDS="amd64 ppc x86"
+IUSE="+glib +libnet static-libs"
+
+RDEPEND="!net-libs/libnids:1.1
+	net-libs/libpcap
+	glib? ( dev-libs/glib:2 )
+	libnet? ( >=net-libs/libnet-1.1.0-r3 )"
+DEPEND="${RDEPEND}"
+BDEPEND="glib? ( virtual/pkgconfig )"
+
+PATCHES=(
+	"${FILESDIR}"/${P}-ldflags.patch
+	"${FILESDIR}"/${P}-libdir.patch
+	"${FILESDIR}"/${P}-static-libs.patch
+	"${FILESDIR}"/${P}-no-inline.patch
+)
+
+src_prepare() {
+	default
+	eautoconf
+}
+
+src_configure() {
+	tc-export AR
+
+	append-flags -fno-strict-aliasing
+
+	econf \
+		--enable-shared \
+		$(usex glib '' --disable-libglib) \
+		$(use_enable libnet)
+}
+
+src_compile() {
+	emake shared $(usex static-libs static '')
+}
+
+src_install() {
+	local tgt
+	for tgt in _installshared $(usex static-libs _install ''); do
+		emake install_prefix="${D}" ${tgt}
+	done
+
+	dodoc CHANGES CREDITS MISC README doc/*
+}
-- 
cgit v1.2.3