From 54654470d999265b5a0010be7190e8a9993b1840 Mon Sep 17 00:00:00 2001
From: V3n3RiX <venerix@koprulu.sector>
Date: Thu, 11 May 2023 17:46:59 +0100
Subject: gentoo auto-resync : 11:05:2023 - 17:46:59

---
 net-libs/libktorrent/libktorrent-23.04.1.ebuild | 60 +++++++++++++++++++++++++
 1 file changed, 60 insertions(+)
 create mode 100644 net-libs/libktorrent/libktorrent-23.04.1.ebuild

(limited to 'net-libs/libktorrent/libktorrent-23.04.1.ebuild')

diff --git a/net-libs/libktorrent/libktorrent-23.04.1.ebuild b/net-libs/libktorrent/libktorrent-23.04.1.ebuild
new file mode 100644
index 000000000000..2ef0c863b832
--- /dev/null
+++ b/net-libs/libktorrent/libktorrent-23.04.1.ebuild
@@ -0,0 +1,60 @@
+# Copyright 1999-2023 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=8
+
+ECM_TEST="forceoptional"
+KDE_ORG_CATEGORY="network"
+KFMIN=5.104.0
+QTMIN=5.15.5
+VIRTUALX_REQUIRED="test"
+inherit ecm gear.kde.org
+
+DESCRIPTION="BitTorrent library based on KDE Frameworks"
+HOMEPAGE="https://apps.kde.org/ktorrent/ https://userbase.kde.org/KTorrent"
+
+LICENSE="GPL-2+"
+SLOT="5"
+KEYWORDS="~amd64 ~arm ~arm64 ~ppc64 ~riscv ~x86"
+IUSE=""
+
+COMMON_DEPEND="
+	>=app-crypt/qca-2.3.0:2[qt5(+)]
+	>=dev-libs/gmp-6.0.0a:0=
+	dev-libs/libgcrypt:0=
+	>=dev-qt/qtnetwork-${QTMIN}:5
+	>=dev-qt/qtxml-${QTMIN}:5
+	>=kde-frameworks/karchive-${KFMIN}:5
+	>=kde-frameworks/kconfig-${KFMIN}:5
+	>=kde-frameworks/kcoreaddons-${KFMIN}:5
+	>=kde-frameworks/kcrash-${KFMIN}:5
+	>=kde-frameworks/ki18n-${KFMIN}:5
+	>=kde-frameworks/kio-${KFMIN}:5
+	>=kde-frameworks/solid-${KFMIN}:5
+"
+DEPEND="${COMMON_DEPEND}
+	>=dev-libs/boost-1.71
+"
+RDEPEND="${COMMON_DEPEND}
+	!dev-libs/botan[gmp(-)]
+"
+BDEPEND="sys-devel/gettext"
+
+src_prepare() {
+	ecm_src_prepare
+
+	# Gentoo workaround because gmp.h in MULTILIB_WRAPPED_HEADERS is breaking this
+	sed -i -e "/^find_package/ s/\"\${LibGMP_MIN_VERSION}\" //" \
+		CMakeLists.txt || die
+	sed -i -e "/^find_dependency/ s/ \"@LibGMP_MIN_VERSION@\"//" \
+		KF5TorrentConfig.cmake.in || die
+}
+
+src_test() {
+	# failing network tests
+	local myctestargs=(
+		-E "(fin|packetloss|send|superseedtest|transmit|utppolltest)"
+	)
+
+	ecm_src_test
+}
-- 
cgit v1.2.3