From d934827bf44b7cfcf6711964418148fa60877668 Mon Sep 17 00:00:00 2001
From: V3n3RiX <venerix@redcorelinux.org>
Date: Wed, 25 Nov 2020 22:39:15 +0000
Subject: gentoo resync : 25.11.2020

---
 net-libs/libhubbub/libhubbub-0.3.7.ebuild | 56 +++++++++++++++++++++++++++++++
 1 file changed, 56 insertions(+)
 create mode 100644 net-libs/libhubbub/libhubbub-0.3.7.ebuild

(limited to 'net-libs/libhubbub/libhubbub-0.3.7.ebuild')

diff --git a/net-libs/libhubbub/libhubbub-0.3.7.ebuild b/net-libs/libhubbub/libhubbub-0.3.7.ebuild
new file mode 100644
index 000000000000..37c534bcee47
--- /dev/null
+++ b/net-libs/libhubbub/libhubbub-0.3.7.ebuild
@@ -0,0 +1,56 @@
+# Copyright 1999-2020 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=7
+
+inherit netsurf flag-o-matic
+
+DESCRIPTION="HTML5 compliant parsing library, written in C"
+HOMEPAGE="https://www.netsurf-browser.org/projects/hubbub/"
+SRC_URI="https://download.netsurf-browser.org/libs/releases/${P}-src.tar.gz"
+
+LICENSE="MIT"
+SLOT="0/${PV}"
+KEYWORDS="~amd64 ~arm ~arm64 ~ppc ~ppc64 ~x86 ~m68k-mint"
+IUSE="doc test"
+
+BDEPEND="
+	dev-util/netsurf-buildsystem
+	virtual/pkgconfig
+	doc? ( app-doc/doxygen )
+	test? ( dev-lang/perl )
+"
+RDEPEND="dev-libs/libparserutils:="
+DEPEND="${RDEPEND}
+	test? ( dev-libs/json-c )"
+RESTRICT="!test? ( test )"
+
+DOCS=( README docs/{Architecture,Macros,Todo,Treebuilder,Updated} )
+PATCHES=( "${FILESDIR}/libhubbub-0.3.6-json-c.patch" )
+
+src_prepare() {
+	default
+	sed -e '1i#pragma GCC diagnostic ignored "-Wimplicit-fallthrough"' \
+		-i test/tree2.c || die
+}
+
+_emake() {
+	netsurf_define_makeconf
+	append-cflags -Wno-error
+	emake "${NETSURF_MAKECONF[@]}" COMPONENT_TYPE=lib-shared $@
+}
+
+src_compile() {
+	_emake
+	use doc && _emake docs
+}
+
+src_test() {
+	_emake test
+}
+
+src_install() {
+	_emake DESTDIR="${D}" install
+	use doc && HTML_DOCS=( docs/html/. )
+	einstalldocs
+}
-- 
cgit v1.2.3