From 0b1a4d018ed7758b9e49f6e4b3b38304f91a8cf5 Mon Sep 17 00:00:00 2001
From: V3n3RiX <venerix@koprulu.sector>
Date: Thu, 18 Aug 2022 02:33:40 +0100
Subject: gentoo auto-resync : 18:08:2022 - 02:33:40

---
 net-libs/libgssglue/libgssglue-0.7.ebuild | 50 +++++++++++++++++++++++++++++++
 1 file changed, 50 insertions(+)
 create mode 100644 net-libs/libgssglue/libgssglue-0.7.ebuild

(limited to 'net-libs/libgssglue/libgssglue-0.7.ebuild')

diff --git a/net-libs/libgssglue/libgssglue-0.7.ebuild b/net-libs/libgssglue/libgssglue-0.7.ebuild
new file mode 100644
index 000000000000..89f5f109a7f7
--- /dev/null
+++ b/net-libs/libgssglue/libgssglue-0.7.ebuild
@@ -0,0 +1,50 @@
+# Copyright 1999-2022 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=8
+
+inherit autotools readme.gentoo-r1
+
+DESCRIPTION="Exports a gssapi interface which calls other random gssapi libraries"
+HOMEPAGE="http://www.citi.umich.edu/projects/nfsv4/linux https://gitlab.com/gsasl/libgssglue"
+SRC_URI="https://gitlab.com/gsasl/libgssglue/-/archive/${P}/${PN}-${P}.tar.bz2"
+S="${WORKDIR}"/${PN}-${P}
+
+LICENSE="BSD"
+SLOT="0"
+KEYWORDS="~alpha ~amd64 ~arm ~arm64 ~hppa ~ia64 ~mips ~ppc ~ppc64 ~riscv ~s390 ~sparc ~x86"
+
+RDEPEND="virtual/krb5"
+
+DOC_CONTENTS="
+This package allows choosing a Kerberos or GSSAPI implementation
+at runtime.
+
+See
+https://blog.josefsson.org/2022/07/14/towards-pluggable-gss-api-modules/
+for more details.
+
+A system-wide implementation can be chosen by editing ${EROOT}/etc/gssapi_mech.conf,
+or it can be set per-process via the GSSAPI_MECH_CONF environment variable.
+"
+
+src_prepare() {
+	default
+
+	eautoreconf
+}
+
+src_install() {
+	default
+
+	readme.gentoo_create_doc
+
+	insinto /etc
+	doins doc/gssapi_mech.conf
+
+	find "${ED}" -name '*.la' -delete || die
+}
+
+pkg_postinst() {
+	readme.gentoo_print_elog
+}
-- 
cgit v1.2.3