From 29aabba0ea759c6a2864ff5631735b67ee38e5e0 Mon Sep 17 00:00:00 2001
From: V3n3RiX <venerix@redcorelinux.org>
Date: Wed, 5 Feb 2020 18:44:56 +0000
Subject: gentoo resync : 05.02.2020

---
 net-libs/libgadu/libgadu-1.12.2-r1.ebuild | 59 +++++++++++++++++++++++++++++++
 1 file changed, 59 insertions(+)
 create mode 100644 net-libs/libgadu/libgadu-1.12.2-r1.ebuild

(limited to 'net-libs/libgadu/libgadu-1.12.2-r1.ebuild')

diff --git a/net-libs/libgadu/libgadu-1.12.2-r1.ebuild b/net-libs/libgadu/libgadu-1.12.2-r1.ebuild
new file mode 100644
index 000000000000..6172f02348e2
--- /dev/null
+++ b/net-libs/libgadu/libgadu-1.12.2-r1.ebuild
@@ -0,0 +1,59 @@
+# Copyright 1999-2020 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=7
+
+inherit autotools
+
+DESCRIPTION="Client-side library for the Gadu-Gadu protocol"
+HOMEPAGE="https://libgadu.net/"
+SRC_URI="https://github.com/wojtekka/${PN}/releases/download/${PV}/${P}.tar.gz"
+
+LICENSE="LGPL-2.1"
+SLOT="0"
+KEYWORDS="amd64 ~arm arm64 ~ia64 ~mips ~ppc ppc64 ~sparc x86 ~amd64-linux ~x86-linux ~ppc-macos"
+IUSE="doc ssl test threads"
+
+RESTRICT="!test? ( test )"
+
+BDEPEND="
+	doc? ( app-doc/doxygen )
+	test? (
+		dev-libs/expat
+		dev-libs/libxml2:2
+		net-misc/curl
+	)
+"
+DEPEND="
+	dev-libs/protobuf-c:=
+	sys-libs/zlib
+	ssl? ( net-libs/gnutls:= )
+"
+RDEPEND="${DEPEND}"
+
+BUILD_DIR="${S}"
+
+DOCS=( AUTHORS ChangeLog NEWS README )
+
+src_prepare() {
+	default
+	eautoreconf
+}
+
+src_configure() {
+	local myeconfargs=(
+		--disable-static
+		--with-protobuf
+		--without-openssl
+		$(use_with ssl gnutls)
+		$(use_enable test tests)
+		$(use_with threads pthread)
+	)
+	econf "${myeconfargs[@]}"
+}
+
+src_install() {
+	use doc && local HTML_DOCS=( docs/html/. )
+	default
+	find "${D}" -name '*.la' -type f -delete || die
+}
-- 
cgit v1.2.3