From 8e5dcbcd9c97dcecc17992eff0e8d01e5c83ade2 Mon Sep 17 00:00:00 2001
From: V3n3RiX <venerix@koprulu.sector>
Date: Wed, 9 Aug 2023 21:30:54 +0100
Subject: gentoo auto-resync : 09:08:2023 - 21:30:54

---
 .../libcloudproviders-0.3.2.ebuild                 | 47 ++++++++++++++++++++++
 1 file changed, 47 insertions(+)
 create mode 100644 net-libs/libcloudproviders/libcloudproviders-0.3.2.ebuild

(limited to 'net-libs/libcloudproviders/libcloudproviders-0.3.2.ebuild')

diff --git a/net-libs/libcloudproviders/libcloudproviders-0.3.2.ebuild b/net-libs/libcloudproviders/libcloudproviders-0.3.2.ebuild
new file mode 100644
index 000000000000..4ea2fe60e264
--- /dev/null
+++ b/net-libs/libcloudproviders/libcloudproviders-0.3.2.ebuild
@@ -0,0 +1,47 @@
+# Copyright 1999-2023 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=8
+
+inherit gnome.org meson-multilib vala
+
+DESCRIPTION="DBus API that allows cloud storage sync clients to expose their services"
+HOMEPAGE="https://gitlab.gnome.org/World/libcloudproviders"
+
+LICENSE="LGPL-3"
+SLOT="0"
+IUSE="gtk-doc +introspection vala"
+REQUIRED_USE="vala? ( introspection )"
+
+KEYWORDS="~alpha ~amd64 ~arm ~arm64 ~ia64 ~loong ~mips ~ppc ~ppc64 ~riscv ~sparc ~x86"
+
+DEPEND="
+	>=dev-libs/glib-2.51.2:2[${MULTILIB_USEDEP}]
+	introspection? ( dev-libs/gobject-introspection )"
+RDEPEND="${DEPEND}"
+BDEPEND="
+	dev-util/gdbus-codegen
+	dev-util/glib-utils
+	virtual/pkgconfig
+	gtk-doc? ( dev-util/gtk-doc )
+	vala? ( $(vala_depend) )
+"
+
+src_prepare() {
+	default
+	use vala && vala_setup
+}
+
+multilib_src_configure() {
+	local emesonargs=(
+		$(meson_native_use_bool gtk-doc enable-gtk-doc)
+		-Dinstalled-tests=false
+		$(meson_native_use_bool introspection)
+		$(meson_native_use_bool vala vapigen)
+	)
+	meson_src_configure
+}
+
+multilib_src_install() {
+	meson_src_install
+}
-- 
cgit v1.2.3