From d934827bf44b7cfcf6711964418148fa60877668 Mon Sep 17 00:00:00 2001
From: V3n3RiX <venerix@redcorelinux.org>
Date: Wed, 25 Nov 2020 22:39:15 +0000
Subject: gentoo resync : 25.11.2020

---
 net-libs/gloox/gloox-1.0.24.ebuild | 60 ++++++++++++++++++++++++++++++++++++++
 1 file changed, 60 insertions(+)
 create mode 100644 net-libs/gloox/gloox-1.0.24.ebuild

(limited to 'net-libs/gloox/gloox-1.0.24.ebuild')

diff --git a/net-libs/gloox/gloox-1.0.24.ebuild b/net-libs/gloox/gloox-1.0.24.ebuild
new file mode 100644
index 000000000000..e7a34c9e3dc3
--- /dev/null
+++ b/net-libs/gloox/gloox-1.0.24.ebuild
@@ -0,0 +1,60 @@
+# Copyright 1999-2020 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=7
+
+inherit autotools
+
+MY_P="${P/_/-}"
+DESCRIPTION="A portable high-level Jabber/XMPP library for C++"
+HOMEPAGE="https://camaya.net/gloox/"
+SRC_URI="https://camaya.net/download/${MY_P}.tar.bz2"
+S="${WORKDIR}/${MY_P}"
+
+LICENSE="GPL-3"
+# Check upstream changelog: https://camaya.net/gloox/changelog/
+SLOT="0/18"
+KEYWORDS="~alpha ~amd64 ~arm ~arm64 ~ia64 ~ppc ~ppc64 ~sparc ~x86"
+IUSE="debug gnutls idn libressl ssl static-libs test zlib"
+RESTRICT="!test? ( test )"
+
+DEPEND="
+	idn? ( net-dns/libidn:= )
+	gnutls? ( net-libs/gnutls:= )
+	ssl? (
+		!libressl? ( dev-libs/openssl:0= )
+		libressl? ( dev-libs/libressl:0= )
+	)
+	zlib? ( sys-libs/zlib )
+"
+RDEPEND="${DEPEND}"
+
+PATCHES=(
+	"${FILESDIR}/${PN}-1.0.24-musl.patch"
+	"${FILESDIR}/${PN}-1.0.24-Makefile.patch"
+)
+
+src_prepare() {
+	default
+	eautoreconf
+}
+
+src_configure() {
+	# Examples are not installed anyway, so - why should we build them?
+	local myeconfargs=(
+		--without-examples
+		$(usex debug "--enable-debug" '')
+		$(use_enable static-libs static)
+		$(use_with idn libidn)
+		$(use_with gnutls)
+		$(use_with ssl openssl)
+		$(use_with test tests)
+		$(use_with zlib)
+	)
+	econf "${myeconfargs[@]}"
+}
+
+src_install() {
+	default
+	find "${ED}" -name "*.la" -delete || die
+}
-- 
cgit v1.2.3