From 0704956f7256f1f618cc5e03af2c1dbd0e83dbc5 Mon Sep 17 00:00:00 2001
From: V3n3RiX <venerix@redcorelinux.org>
Date: Thu, 16 Jan 2020 16:18:18 +0000
Subject: gentoo resync : 16.01.2020

---
 net-libs/aqbanking/aqbanking-5.99.45.ebuild | 65 +++++++++++++++++++++++++++++
 1 file changed, 65 insertions(+)
 create mode 100644 net-libs/aqbanking/aqbanking-5.99.45.ebuild

(limited to 'net-libs/aqbanking/aqbanking-5.99.45.ebuild')

diff --git a/net-libs/aqbanking/aqbanking-5.99.45.ebuild b/net-libs/aqbanking/aqbanking-5.99.45.ebuild
new file mode 100644
index 000000000000..10103090ff06
--- /dev/null
+++ b/net-libs/aqbanking/aqbanking-5.99.45.ebuild
@@ -0,0 +1,65 @@
+# Copyright 1999-2020 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=7
+
+MY_P="${P/_beta/beta}"
+
+DESCRIPTION="Generic Online Banking Interface"
+HOMEPAGE="https://www.aquamaniac.de/sites/aqbanking/index.php"
+SRC_URI="https://www.aquamaniac.de/rdm/attachments/download/232/${MY_P}.tar.gz"
+
+LICENSE="GPL-2"
+SLOT="0"
+KEYWORDS="~amd64 ~ppc ~ppc64 ~x86"
+IUSE="debug doc ebics examples ofx"
+
+BDEPEND="
+	sys-devel/gettext
+	virtual/pkgconfig
+	doc? ( app-doc/doxygen )
+"
+DEPEND="
+	app-misc/ktoblzcheck
+	dev-libs/gmp:0=
+	>=sys-libs/gwenhywfar-5.1.1:=
+	virtual/libintl
+	ebics? ( dev-libs/xmlsec[gcrypt,gnutls] )
+	ofx? ( >=dev-libs/libofx-0.9.5 )
+"
+RDEPEND="${DEPEND}"
+
+DOCS=( AUTHORS ChangeLog NEWS README TODO )
+
+MAKEOPTS="${MAKEOPTS} -j1" # 5.7.8 still fails with > -j1
+
+S="${WORKDIR}/${MY_P}"
+
+src_configure() {
+	local backends="aqhbci aqnone aqpaypal"
+	use ofx && backends="${backends} aqofxconnect"
+	use ebics && backends="${backends} aqebics"
+
+	local myeconfargs=(
+		--with-docpath=/usr/share/doc/${PF}/apidoc
+		$(use_enable debug)
+		$(use_enable doc full-doc)
+		--with-backends="${backends}"
+	)
+	econf "${myeconfargs[@]}"
+}
+
+src_install() {
+	emake DESTDIR="${D}" install
+
+	rm -rv "${ED}"/usr/share/doc/ || die
+
+	einstalldocs
+
+	if use examples; then
+		docinto tutorials
+		dodoc tutorials/*.{c,h} tutorials/README
+	fi
+
+	find "${D}" -name '*.la' -type f -delete || die
+}
-- 
cgit v1.2.3