From 5d0c50eb490582cf1277e150ee5bb63a90b85aa6 Mon Sep 17 00:00:00 2001
From: V3n3RiX <venerix@koprulu.sector>
Date: Tue, 22 Nov 2022 13:06:25 +0000
Subject: gentoo auto-resync : 22:11:2022 - 13:06:24

---
 net-irc/scrollz/scrollz-2.3.1.ebuild | 69 ++++++++++++++++++++++++++++++++++++
 1 file changed, 69 insertions(+)
 create mode 100644 net-irc/scrollz/scrollz-2.3.1.ebuild

(limited to 'net-irc/scrollz/scrollz-2.3.1.ebuild')

diff --git a/net-irc/scrollz/scrollz-2.3.1.ebuild b/net-irc/scrollz/scrollz-2.3.1.ebuild
new file mode 100644
index 000000000000..52ce5f27eb02
--- /dev/null
+++ b/net-irc/scrollz/scrollz-2.3.1.ebuild
@@ -0,0 +1,69 @@
+# Copyright 1999-2022 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=8
+
+inherit autotools flag-o-matic toolchain-funcs
+
+MY_P="ScrollZ-${PV}"
+
+DESCRIPTION="Advanced IRC client based on ircII"
+HOMEPAGE="https://www.scrollz.info/"
+SRC_URI="https://www.scrollz.info/download/${MY_P}.tar.gz"
+SRC_URI+=" https://dev.gentoo.org/~sam/distfiles/${CATEGORY}/${PN}/${P}-patches.tar.xz"
+S="${WORKDIR}/${MY_P}"
+
+LICENSE="BSD"
+SLOT="0"
+KEYWORDS="~amd64 ~ppc ~riscv ~x86 ~amd64-linux ~x86-linux ~ppc-macos"
+IUSE="gmp gnutls ipv6 ssl"
+REQUIRED_USE="gnutls? ( ssl )"
+
+BDEPEND="virtual/pkgconfig"
+DEPEND="
+	sys-libs/ncurses:=
+	virtual/libcrypt:=
+	gmp? ( dev-libs/gmp:= )
+	ssl? (
+		gnutls? ( net-libs/gnutls:= )
+		!gnutls? ( dev-libs/openssl:= )
+	)
+"
+RDEPEND="${DEPEND}"
+
+PATCHES=(
+	# https://github.com/ScrollZ/ScrollZ/pull/30
+	"${WORKDIR}"/${P}-patches
+)
+
+src_configure() {
+	# Many -Wdeprecated-non-prototype warnings
+	append-cflags -std=gnu89
+
+	local _myssl
+
+	if use ssl; then
+		if use gnutls; then
+			_myssl="--with-ssl"
+		else
+			_myssl="--with-openssl"
+		fi
+	fi
+
+	tc-export CC #397441, ancient autoconf
+	econf \
+		--with-default-server="irc.gentoo.org" \
+		$(use_enable ipv6) \
+		--enable-regexp \
+		$(use_enable gmp fish) \
+		${_myssl}
+}
+
+src_install() {
+	emake \
+		DESTDIR="${ED}" \
+		mandir="${EPREFIX}/usr/share/man/man1" \
+		install
+
+	dodoc ChangeLog* NEWS README* todo
+}
-- 
cgit v1.2.3