From d18bf1e01b65ee4bf0c804e2843b282d3d4e5d7c Mon Sep 17 00:00:00 2001
From: V3n3RiX <venerix@redcorelinux.org>
Date: Tue, 15 Jun 2021 14:57:03 +0100
Subject: gentoo resync : 15.06.2021

---
 net-irc/eggdrop/eggdrop-1.9.1.ebuild | 72 ++++++++++++++++++++++++++++++++++++
 1 file changed, 72 insertions(+)
 create mode 100644 net-irc/eggdrop/eggdrop-1.9.1.ebuild

(limited to 'net-irc/eggdrop/eggdrop-1.9.1.ebuild')

diff --git a/net-irc/eggdrop/eggdrop-1.9.1.ebuild b/net-irc/eggdrop/eggdrop-1.9.1.ebuild
new file mode 100644
index 000000000000..5d6de0a857df
--- /dev/null
+++ b/net-irc/eggdrop/eggdrop-1.9.1.ebuild
@@ -0,0 +1,72 @@
+# Copyright 1999-2021 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=7
+
+inherit readme.gentoo-r1
+
+MY_P="${PN}-${PV/_rc/rc}"
+DESCRIPTION="An IRC bot extensible with C or TCL"
+HOMEPAGE="https://www.eggheads.org/"
+SRC_URI="https://ftp.eggheads.org/pub/eggdrop/source/${PV:0:3}/${MY_P}.tar.gz"
+S="${WORKDIR}/${MY_P}"
+
+KEYWORDS="~alpha ~amd64 ~arm ~arm64 ~ia64 ~mips ~ppc ~sparc ~x86"
+LICENSE="GPL-2+"
+SLOT="0"
+IUSE="debug doc ipv6 ssl static"
+
+DEPEND="
+	dev-lang/tcl:0=
+	ssl? ( dev-libs/openssl:0= )
+"
+RDEPEND="
+	sys-apps/gentoo-functions
+	${DEPEND}
+"
+
+DOCS=( AUTHORS FEATURES INSTALL NEWS README THANKS UPGRADING )
+
+src_configure() {
+	econf $(use_enable ssl tls) \
+		$(use_enable ipv6 ipv6)
+
+	emake config
+}
+
+src_compile() {
+	local target
+
+	if use static && use debug; then
+		target="sdebug"
+	elif use static; then
+		target="static"
+	elif use debug; then
+		target="debug"
+	fi
+
+	emake ${target}
+}
+
+src_install() {
+	emake DEST="${D}"/opt/eggdrop install
+
+	use doc && HTML_DOCS=( doc/html/. )
+	rm -r "${D}"/opt/eggdrop/doc/html || die
+	DOC_CONTENTS="
+		Additional documentation can be found
+		in ${EPREFIX}/opt/eggdrop/doc
+	"
+	readme.gentoo_create_doc
+	einstalldocs
+
+	dobin "${FILESDIR}"/eggdrop-installer
+	doman doc/man1/eggdrop.1
+}
+
+pkg_postinst() {
+	# Only display this for new installs
+	if [[ -z ${REPLACING_VERSIONS} ]]; then
+		elog "Please run ${EPREFIX}/usr/bin/eggdrop-installer to install your eggdrop bot."
+	fi
+}
-- 
cgit v1.2.3