From 0f558761aa2dee1017b4751e4017205e015a9560 Mon Sep 17 00:00:00 2001
From: V3n3RiX <venerix@koprulu.sector>
Date: Wed, 29 Jun 2022 12:04:12 +0100
Subject: gentoo resync : 29.12.2022

---
 .../telegram-desktop-bin-4.0.2.ebuild              | 52 ++++++++++++++++++++++
 1 file changed, 52 insertions(+)
 create mode 100644 net-im/telegram-desktop-bin/telegram-desktop-bin-4.0.2.ebuild

(limited to 'net-im/telegram-desktop-bin/telegram-desktop-bin-4.0.2.ebuild')

diff --git a/net-im/telegram-desktop-bin/telegram-desktop-bin-4.0.2.ebuild b/net-im/telegram-desktop-bin/telegram-desktop-bin-4.0.2.ebuild
new file mode 100644
index 000000000000..d0558b783945
--- /dev/null
+++ b/net-im/telegram-desktop-bin/telegram-desktop-bin-4.0.2.ebuild
@@ -0,0 +1,52 @@
+# Copyright 1999-2022 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=8
+
+inherit desktop optfeature xdg
+
+DESCRIPTION="Official desktop client for Telegram (binary package)"
+HOMEPAGE="https://desktop.telegram.org"
+SRC_URI="
+	https://github.com/telegramdesktop/tdesktop/archive/v${PV}.tar.gz -> tdesktop-${PV}.tar.gz
+	amd64? ( https://updates.tdesktop.com/tlinux/tsetup.${PV}.tar.xz )
+"
+
+LICENSE="GPL-3-with-openssl-exception"
+SLOT="0"
+KEYWORDS="-* ~amd64"
+
+QA_PREBUILT="usr/bin/telegram-desktop"
+
+RDEPEND="
+	sys-libs/glibc
+	dev-libs/glib:2
+	>=media-libs/fontconfig-2.13
+	media-libs/freetype:2
+	virtual/opengl
+	x11-libs/libX11
+	>=x11-libs/libxcb-1.10[xkb]
+"
+
+S="${WORKDIR}/Telegram"
+
+src_install() {
+	newbin Telegram telegram-desktop
+
+	insinto /etc/tdesktop
+	newins - externalupdater <<<"${EPREFIX}/usr/bin/telegram-desktop"
+
+	local icon_size
+	for icon_size in 16 32 48 64 128 256 512; do
+		newicon -s "${icon_size}" \
+			"${WORKDIR}/tdesktop-${PV}/Telegram/Resources/art/icon${icon_size}.png" \
+			telegram.png
+	done
+
+	domenu "${WORKDIR}/tdesktop-${PV}"/lib/xdg/telegramdesktop.desktop
+}
+
+pkg_postinst() {
+	xdg_pkg_postinst
+	optfeature "spell checker support" app-text/enchant
+}
-- 
cgit v1.2.3