From 30737dc88991519b90363c2c7bae8fd049098d13 Mon Sep 17 00:00:00 2001
From: V3n3RiX <venerix@koprulu.sector>
Date: Fri, 14 Oct 2022 01:43:18 +0100
Subject: gentoo auto-resync : 14:10:2022 - 01:43:18

---
 net-im/profanity/profanity-0.13.1.ebuild | 71 ++++++++++++++++++++++++++++++++
 1 file changed, 71 insertions(+)
 create mode 100644 net-im/profanity/profanity-0.13.1.ebuild

(limited to 'net-im/profanity/profanity-0.13.1.ebuild')

diff --git a/net-im/profanity/profanity-0.13.1.ebuild b/net-im/profanity/profanity-0.13.1.ebuild
new file mode 100644
index 000000000000..9618e1bd64fe
--- /dev/null
+++ b/net-im/profanity/profanity-0.13.1.ebuild
@@ -0,0 +1,71 @@
+# Copyright 1999-2022 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=8
+
+DESCRIPTION="A console based XMPP client inspired by Irssi"
+HOMEPAGE="https://profanity-im.github.io"
+SRC_URI="https://github.com/profanity-im/profanity/releases/download/${PV}/${P}.tar.xz"
+
+LICENSE="GPL-3"
+SLOT="0"
+KEYWORDS="~amd64"
+IUSE="libnotify omemo otr gpg test xscreensaver"
+RESTRICT="!test? ( test )"
+
+RDEPEND="
+	dev-db/sqlite:3
+	|| ( app-accessibility/at-spi2-atk dev-libs/atk )
+	dev-libs/glib:2
+	dev-libs/libassuan
+	dev-libs/libgpg-error
+	>=dev-libs/libstrophe-0.12.2
+	media-libs/harfbuzz:=
+	net-misc/curl
+	sys-libs/ncurses:=[unicode(+)]
+	sys-libs/readline:=
+	x11-libs/cairo
+	x11-libs/gdk-pixbuf:2
+	x11-libs/gtk+:3
+	x11-libs/pango
+	x11-misc/shared-mime-info
+	virtual/libcrypt:=
+	gpg? ( app-crypt/gpgme:= )
+	libnotify? ( x11-libs/libnotify )
+	omemo? (
+		dev-libs/libgcrypt:=
+		net-libs/libsignal-protocol-c
+	)
+	otr? ( net-libs/libotr )
+	xscreensaver? (
+		x11-libs/libXScrnSaver
+		x11-libs/libX11
+	)
+"
+DEPEND="
+	${RDEPEND}
+	test? ( dev-util/cmocka )
+"
+
+src_configure() {
+	local myeconfargs=(
+		--enable-gdk-pixbuf
+		$(use_enable libnotify notifications)
+		$(use_enable omemo)
+		$(use_enable otr)
+		$(use_enable gpg pgp)
+		$(use_with xscreensaver)
+	)
+
+	econf "${myeconfargs[@]}"
+}
+
+src_compile() {
+	emake CFLAGS="${CFLAGS}"
+}
+
+src_install() {
+	default
+
+	find "${ED}" -type f -name '*.la' -delete || die
+}
-- 
cgit v1.2.3