From da7ae1dd1fccb6b3c0e4763ab983ad96d57bf463 Mon Sep 17 00:00:00 2001
From: V3n3RiX <venerix@koprulu.sector>
Date: Sat, 20 Apr 2024 12:05:24 +0100
Subject: gentoo auto-resync : 20:04:2024 - 12:05:23

---
 net-fs/davfs2/davfs2-1.6.1-r3.ebuild | 59 ++++++++++++++++++++++++++++++++++++
 1 file changed, 59 insertions(+)
 create mode 100644 net-fs/davfs2/davfs2-1.6.1-r3.ebuild

(limited to 'net-fs/davfs2/davfs2-1.6.1-r3.ebuild')

diff --git a/net-fs/davfs2/davfs2-1.6.1-r3.ebuild b/net-fs/davfs2/davfs2-1.6.1-r3.ebuild
new file mode 100644
index 000000000000..4685ec7210b8
--- /dev/null
+++ b/net-fs/davfs2/davfs2-1.6.1-r3.ebuild
@@ -0,0 +1,59 @@
+# Copyright 1999-2024 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=8
+
+inherit autotools
+
+DESCRIPTION="Linux FUSE (or coda) driver that allows you to mount a WebDAV resource"
+HOMEPAGE="https://savannah.nongnu.org/projects/davfs2"
+SRC_URI="mirror://nongnu/${PN}/${P}.tar.gz"
+
+LICENSE="GPL-3+"
+SLOT="0"
+KEYWORDS="~amd64 ~arm ~arm64 ~ppc ~x86"
+IUSE="nls"
+RESTRICT="test"
+
+RDEPEND="dev-libs/libxml2
+	acct-group/davfs2
+	acct-user/davfs2
+	net-libs/neon:0/27
+	sys-libs/zlib
+	nls? ( virtual/libintl virtual/libiconv )
+"
+BDEPEND="
+	nls? ( sys-devel/gettext )
+"
+
+PATCHES=(
+	"${FILESDIR}"/${PN}-1.6.1-neon-version-support.patch
+)
+
+src_prepare() {
+	local f
+
+	# Let the package manager handle man page compression
+	while IFS="" read -d $'\0' -r f ; do
+		sed -e '/^manual[58]_DATA/ s/[.]gz//g' -i "${f}" || die
+	done < <(find "${S}"/man -type f -name 'Makefile.am' -print0)
+
+	default
+	eautoreconf
+}
+
+src_configure() {
+	econf --enable-largefile $(use_enable nls) ssbindir="${EPREFIX}/usr/sbin"
+}
+
+pkg_postinst() {
+	elog
+	elog "Quick setup:"
+	elog "   (as root)"
+	elog "   # gpasswd -a \${your_user} davfs2"
+	elog "   # echo 'https://path/to/dav /home/\${your_user}/dav davfs rw,user,noauto  0  0' >> /etc/fstab"
+	elog "   (as user)"
+	elog "   \$ mkdir -p ~/dav"
+	elog "   \$ mount ~/dav"
+	elog
+}
-- 
cgit v1.2.3