From 0f558761aa2dee1017b4751e4017205e015a9560 Mon Sep 17 00:00:00 2001
From: V3n3RiX <venerix@koprulu.sector>
Date: Wed, 29 Jun 2022 12:04:12 +0100
Subject: gentoo resync : 29.12.2022

---
 net-dns/hash-slinger/hash-slinger-3.2.ebuild | 49 ++++++++++++++++++++++++++++
 1 file changed, 49 insertions(+)
 create mode 100644 net-dns/hash-slinger/hash-slinger-3.2.ebuild

(limited to 'net-dns/hash-slinger/hash-slinger-3.2.ebuild')

diff --git a/net-dns/hash-slinger/hash-slinger-3.2.ebuild b/net-dns/hash-slinger/hash-slinger-3.2.ebuild
new file mode 100644
index 000000000000..467f00926cfa
--- /dev/null
+++ b/net-dns/hash-slinger/hash-slinger-3.2.ebuild
@@ -0,0 +1,49 @@
+# Copyright 1999-2022 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=8
+
+PYTHON_COMPAT=( python3_{8..11} )
+
+inherit python-single-r1
+
+DESCRIPTION="Various tools to generate DNS records like SSHFP, TLSA, OPENPGPKEY, IPSECKEY"
+HOMEPAGE="https://github.com/letoams/hash-slinger"
+SRC_URI="https://github.com/letoams/${PN}/archive/${PV}.tar.gz -> ${P}.tar.gz"
+
+LICENSE="GPL-2+"
+SLOT="0"
+KEYWORDS="~amd64 ~arm ~x86"
+IUSE="ipsec +openpgp +ssh"
+
+REQUIRED_USE="${PYTHON_REQUIRED_USE}"
+
+RDEPEND="
+	${PYTHON_DEPS}
+	$(python_gen_cond_dep '
+		dev-python/dnspython[${PYTHON_USEDEP}]
+		dev-python/ipaddr[${PYTHON_USEDEP}]
+		dev-python/m2crypto[${PYTHON_USEDEP}]
+	')
+	net-dns/unbound[python,${PYTHON_SINGLE_USEDEP}]
+	ipsec? ( net-vpn/libreswan[dnssec] )
+	openpgp? ( $(python_gen_cond_dep 'dev-python/python-gnupg[${PYTHON_USEDEP}]') )
+	ssh? ( net-misc/openssh )
+"
+
+src_install() {
+	local tools tool
+
+	tools="tlsa"
+
+	use ssh	&& tools+=" sshfp"
+	use openpgp && tools+=" openpgpkey"
+	use ipsec && tools+=" ipseckey"
+
+	for tool in $tools ; do
+		doman ${tool}.1
+		python_doscript ${tool}
+	done
+
+	dodoc BUGS CHANGES README
+}
-- 
cgit v1.2.3