From 78634f348a30a55cc55606ee1ecde032241ceaeb Mon Sep 17 00:00:00 2001
From: V3n3RiX <venerix@koprulu.sector>
Date: Sun, 19 Mar 2023 06:33:49 +0000
Subject: gentoo auto-resync : 19:03:2023 - 06:33:49

---
 net-analyzer/zmap/zmap-2.1.1-r5.ebuild | 56 ++++++++++++++++++++++++++++++++++
 1 file changed, 56 insertions(+)
 create mode 100644 net-analyzer/zmap/zmap-2.1.1-r5.ebuild

(limited to 'net-analyzer/zmap/zmap-2.1.1-r5.ebuild')

diff --git a/net-analyzer/zmap/zmap-2.1.1-r5.ebuild b/net-analyzer/zmap/zmap-2.1.1-r5.ebuild
new file mode 100644
index 000000000000..97210a199bd6
--- /dev/null
+++ b/net-analyzer/zmap/zmap-2.1.1-r5.ebuild
@@ -0,0 +1,56 @@
+# Copyright 1999-2023 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=8
+
+inherit cmake fcaps
+
+DESCRIPTION="Fast network scanner designed for Internet-wide network surveys"
+HOMEPAGE="https://zmap.io/"
+SRC_URI="https://github.com/zmap/zmap/archive/v${PV}.tar.gz -> ${P}.tar.gz"
+
+LICENSE="Apache-2.0"
+SLOT="0"
+KEYWORDS="amd64 arm ~arm64 x86"
+IUSE="mongo redis"
+
+RDEPEND="
+	dev-libs/gmp:=
+	net-libs/libpcap
+	dev-libs/json-c:=
+	mongo? (
+		dev-db/mongodb
+		dev-libs/mongo-c-driver
+	)
+	redis? ( dev-libs/hiredis:= )
+"
+DEPEND="${RDEPEND}"
+BDEPEND="
+	dev-util/gengetopt
+	sys-devel/flex
+	dev-util/byacc
+"
+
+PATCHES=(
+	"${FILESDIR}"/${PN}-2.1.1-always-install-config.patch
+)
+
+FILECAPS=( cap_net_raw=ep usr/sbin/zmap )
+
+src_prepare() {
+	sed \
+		-e '/ggo/s:CMAKE_CURRENT_SOURCE_DIR}:CMAKE_BINARY_DIR}/src:g' \
+		-i src/CMakeLists.txt || die
+	cmake_src_prepare
+}
+
+src_configure() {
+	local mycmakeargs=(
+		-DENABLE_DEVELOPMENT=OFF
+		-DWITH_WERROR=OFF
+		-DWITH_MONGO="$(usex mongo)"
+		-DWITH_REDIS="$(usex redis)"
+	)
+
+	cmake_src_configure
+}
-- 
cgit v1.2.3