From 64e107b9b6058580ff0432107eb37cefb0b2a7d8 Mon Sep 17 00:00:00 2001
From: V3n3RiX <venerix@redcorelinux.org>
Date: Mon, 22 Oct 2018 11:09:47 +0100
Subject: gentoo resync : 22.10.2018

---
 net-analyzer/testssl/Manifest                   |  1 +
 net-analyzer/testssl/testssl-2.9.5_p5-r2.ebuild | 74 +++++++++++++++++++++++++
 2 files changed, 75 insertions(+)
 create mode 100644 net-analyzer/testssl/testssl-2.9.5_p5-r2.ebuild

(limited to 'net-analyzer/testssl')

diff --git a/net-analyzer/testssl/Manifest b/net-analyzer/testssl/Manifest
index fc2f228394c5..8a0e65b7a8da 100644
--- a/net-analyzer/testssl/Manifest
+++ b/net-analyzer/testssl/Manifest
@@ -1,4 +1,5 @@
 DIST testssl-2.9.5_p5.tar.gz 8955523 BLAKE2B dcafb0931ddfb9d653acf79f72d2e30b2acc4a80246ecb3f26eaa35d4a69d5af65123005de34d09c563978593450895bf451b866182fd3ea38bdb121fb8e9385 SHA512 8a26989e1b8f45a2ac25efab500c89eeec2dbdbb9c0af715a61433ce0737ed69221df09a9554b6ae4415081a66ef4f6afd44c92405afefe4a810cb4375988700
 EBUILD testssl-2.9.5_p5-r1.ebuild 1291 BLAKE2B dde1e0edccf415dc4f717515e6fb8f333e935215e6452c3457fd203153e523bdf4546a03aef68defee5234359d75d6ab8f74ad91a2504a2b4695e80b601fdd5d SHA512 6ec8005eb3a27a079e800d21b5b03382435e32e8fd9b1def669b464400cdcb182598b3a9f6ece631defc0ae2549fdebeed4f6da4c182929d227e6d63139a60ba
+EBUILD testssl-2.9.5_p5-r2.ebuild 1529 BLAKE2B 989592309812555613fd5d6ecff8173fe1c1bbe384aad4d406f8a827911037e459c1627b08ccf5f0f0f5f20c95f68f9eee0f358c77476d3f985c481d9b6cd6b3 SHA512 e1e6277065413fa8f80a734b008a60ace4ce7275981ff3a2f1d15ca960d69f124545496c39d86228b7f6cf605bf8d56edb48b6446dd54839417c9b75431deb04
 EBUILD testssl-2.9.5_p5.ebuild 1477 BLAKE2B a26cf73f44a63fe823838d748d943cf8e910fa36efc86b13a900af29a17c08061012fa66c07810473c5e9fa43ab6e49290903ebe8beaa2b2407529d7b4350436 SHA512 e217b3f116f62202485715a917f18ea32d902bcd0514dfaa9f5ddc6d3e435df76885daac253243dad99a812f31f51239c8dff6c886b1c376d3f6138f52639780
 MISC metadata.xml 427 BLAKE2B 5504150e6ed2e079db47b71afd8826e0543162d259ffb690caab572f6f87cf358ec4216b7859c274047f4d880aed40ab6858633856e12f9d9d05683198b75fba SHA512 83dacfa2293a8f14bce97a01f732376e76f84c4eb4fffbed1049b08210850cc5b54381d83df15bec2ecc1c1a592148d538ac37053b36fa1022542e023a97d9ab
diff --git a/net-analyzer/testssl/testssl-2.9.5_p5-r2.ebuild b/net-analyzer/testssl/testssl-2.9.5_p5-r2.ebuild
new file mode 100644
index 000000000000..2cabe7984eb1
--- /dev/null
+++ b/net-analyzer/testssl/testssl-2.9.5_p5-r2.ebuild
@@ -0,0 +1,74 @@
+# Copyright 1999-2018 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=7
+
+MY_PN="${PN}.sh"
+MY_PV="${PV/_p/-}"
+
+DESCRIPTION="Tool to check TLS/SSL cipher support"
+HOMEPAGE="https://testssl.sh/"
+SRC_URI="https://github.com/drwetter/${MY_PN}/archive/v${MY_PV}.tar.gz -> ${P}.tar.gz"
+
+LICENSE="GPL-2 bundled-openssl? ( openssl )"
+SLOT="0"
+KEYWORDS="~amd64 ~x86"
+IUSE="bundled-openssl kerberos"
+
+RDEPEND="
+	app-shells/bash[net]
+	net-dns/bind-tools
+	sys-apps/util-linux
+	sys-libs/ncurses:0
+	sys-process/procps
+	bundled-openssl? (
+		kerberos? (
+			sys-libs/zlib
+			virtual/krb5
+		)
+	)
+	!bundled-openssl? ( dev-libs/openssl:0 )
+"
+
+S=${WORKDIR}/${MY_PN}-${MY_PV}
+
+QA_PREBUILT="opt/${PN}/*"
+
+pkg_setup() {
+	if use amd64; then
+		if use kerberos; then
+			BUNDLED_OPENSSL="openssl.Linux.x86_64.krb5"
+		else
+			BUNDLED_OPENSSL="openssl.Linux.x86_64"
+		fi
+	elif use x86; then
+		BUNDLED_OPENSSL="openssl.Linux.i686"
+	fi
+}
+
+src_prepare() {
+	default
+	sed -i ${PN}.sh \
+		-e 's|TESTSSL_INSTALL_DIR="${TESTSSL_INSTALL_DIR:-""}"|TESTSSL_INSTALL_DIR="/"|' \
+		-e 's|$TESTSSL_INSTALL_DIR/etc/|&testssl/|g' || die
+
+	if use bundled-openssl; then
+		sed -i ${PN}.sh \
+			-e "/find_openssl_binary()/a OPENSSL=\"/opt/${PN}/${BUNDLED_OPENSSL}\"" || die
+	fi
+}
+
+src_install() {
+	dodoc CHANGELOG.stable-releases.txt CREDITS.md Readme.md
+	dodoc openssl-rfc.mappping.html
+
+	dobin ${PN}.sh
+
+	insinto /etc/${PN}
+	doins etc/*
+
+	if use bundled-openssl; then
+		exeinto /opt/${PN}
+		use amd64 && doexe bin/${BUNDLED_OPENSSL}
+	fi
+}
-- 
cgit v1.2.3