From 21435953e16cda318a82334ddbadb3b5c36d9ea7 Mon Sep 17 00:00:00 2001
From: V3n3RiX <venerix@redcorelinux.org>
Date: Wed, 15 Jan 2020 15:51:32 +0000
Subject: gentoo resync : 15.01.2020

---
 net-analyzer/ipguard/ipguard-1.04-r1.ebuild | 61 +++++++++++++++++++++++++++++
 1 file changed, 61 insertions(+)
 create mode 100644 net-analyzer/ipguard/ipguard-1.04-r1.ebuild

(limited to 'net-analyzer/ipguard/ipguard-1.04-r1.ebuild')

diff --git a/net-analyzer/ipguard/ipguard-1.04-r1.ebuild b/net-analyzer/ipguard/ipguard-1.04-r1.ebuild
new file mode 100644
index 000000000000..a30baf79b5e9
--- /dev/null
+++ b/net-analyzer/ipguard/ipguard-1.04-r1.ebuild
@@ -0,0 +1,61 @@
+# Copyright 1999-2020 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=7
+inherit toolchain-funcs
+
+DESCRIPTION="Tool designed to protect LAN IP adress space by ARP spoofing"
+HOMEPAGE="http://ipguard.deep.perm.ru/"
+SRC_URI="http://ipguard.deep.perm.ru/files/${P}.tar.gz"
+
+LICENSE="BSD-2"
+SLOT="0"
+KEYWORDS="~amd64 ~x86"
+
+DEPEND="
+	net-libs/libnet:1.1
+	net-libs/libpcap
+"
+RDEPEND="
+	${DEPEND}
+"
+
+src_prepare() {
+	default
+
+	sed -i \
+		-e 's|-g ||g' \
+		-e 's|	@$(CC)|	$(CC)|g' \
+		-e 's| -s | |g' \
+		-e 's| -o | $(CFLAGS) $(LDFLAGS)&|g' \
+		-e 's|$(PREFIX)|${D}&|g' \
+		-e 's|/man/|/share&|g' \
+		Makefile || die
+	sed -i \
+		-e 's|opts=|extra_commands=|g' \
+		-e 's|/var/run/|/run/|g' \
+		-e 's|-u 300 -xz|${OPTS} ${IFACE}|g' \
+		doc/${PN}.gentoo || die
+	sed -i \
+		-e 's|/var/run/|/run/|g' \
+		doc/${PN}.8 ${PN}.h || die
+}
+
+src_compile() {
+	emake \
+		CC=$(tc-getCC) \
+		LIBNET_CONFIG="$(tc-getPKG_CONFIG) libnet" \
+		PREFIX=\"${EPREFIX:-/usr}\"
+}
+
+src_install() {
+	emake \
+		DESTDIR="${D}" \
+		LIBNET_CONFIG="$(tc-getPKG_CONFIG) libnet" \
+		PREFIX=\"${EPREFIX:-/usr}\" \
+		install
+
+	newinitd doc/${PN}.gentoo ${PN}
+	newconfd "${FILESDIR}"/${PN}.confd ${PN}
+	dodoc doc/{NEWS,README*,ethers.sample}
+}
-- 
cgit v1.2.3