From 81ab1a4db30480fdfb51d6e784b0f3ad9bbe2432 Mon Sep 17 00:00:00 2001
From: V3n3RiX <venerix@koprulu.sector>
Date: Sun, 18 Jun 2023 01:46:36 +0100
Subject: gentoo auto-resync : 18:06:2023 - 01:46:36

---
 media-video/qmplay2/Manifest                |   2 +
 media-video/qmplay2/qmplay2-23.06.17.ebuild | 135 ++++++++++++++++++++++++++++
 2 files changed, 137 insertions(+)
 create mode 100644 media-video/qmplay2/qmplay2-23.06.17.ebuild

(limited to 'media-video/qmplay2')

diff --git a/media-video/qmplay2/Manifest b/media-video/qmplay2/Manifest
index 2cfd6183afa8..85e310b3e884 100644
--- a/media-video/qmplay2/Manifest
+++ b/media-video/qmplay2/Manifest
@@ -1,7 +1,9 @@
 AUX qmplay2-23.02.05-fix-libva-glx.patch 619 BLAKE2B c3aeeb812c6012bd4627b984f2fb769e88897030f9f73920102d0e95c179773854ab58002cc97b2df4ba1cea317d725a1a8e0e180143677f16067d6f96a32c73 SHA512 1ae7ab4b443e3ab439fe33748c33484f1d83a20a39d5c9c14a292c9327a4bcd2b1e0c3c456bb82aff6fca84a3e9039174e6f4d2e0beeba3b2427acbd3c389c80
 DIST QMPlay2-src-23.02.05.tar.xz 1428992 BLAKE2B 7296ed089306e50e1051c33c23dae30f14cbb166b9d9ea8c184e8aa027a261a658e1d7770c7d574784a5cde4890c66e2104927f4473f484562378c956bea4b3f SHA512 d2e998a2df08c98b7e0232de693ee17b5c703793e2b1edadde300ca39998f40f7ad58b5850ee1f8cddf1dd9489c7f96e664db7e9deba01a612d97707aad849c0
 DIST QMPlay2-src-23.06.04.tar.xz 1431232 BLAKE2B 7b50e7d28ab9025d7745114c7ee6036df1e1b23b34422ed4097f1ba4e68874efc58a0de68a5635e30cbdb2205777fbdc4f67f759f54cda7e2f926560e4bbc7af SHA512 7e6afb5830b5febd79aa2232d38ccb3483104dd89d20e7476027a7febfd770ccd1df7e6915543df379985d89d307bd1c3bbc8ebc8cc00f440b51e347ddbec0d5
+DIST QMPlay2-src-23.06.17.tar.xz 1432852 BLAKE2B 50512d89f443218bf89f1b54276ece0983d31cc1e563ef829396ed1fb4e5f0437cd25e5ccb3c426ecd668c334477024de8658594c59ae2781a0e54ff83653357 SHA512 62122533a9cfc7aebdbe28166d60816eea21e9c38df5f381817d01aac25a6f10bf806b5a6ccd24cb8fe4b6c7391138226c7a967fab019ad2dcd605797d8d6a28
 EBUILD qmplay2-23.02.05-r1.ebuild 3384 BLAKE2B b1aafd1b3346798f1f1b676627902ca24ccd38eee721b16fea9055698d8c5806f9e64a5e79a2a956fd32e779f904a79eb0c79c9471b146ffc33aedb7bce2e84b SHA512 efd26725ef9b00c214c506c106026e2eb99026aef1386178f24ccf073288df4c2ade3d98e9495b74835c388cab0c63807734edb4154d199f5ff7646c22d3c6ae
 EBUILD qmplay2-23.06.04.ebuild 3344 BLAKE2B ae7d7de6551f46490b7ce7e5e8a9d163c62b3b64f9d327a70c3d139f51556c2b142050fa10534f8c218f5750628f885ac3a1022291a167b806ad446d5e17c518 SHA512 c23e0a10093113e7bb4eae95be33fde3f7f4110a8aa2894c6a302163ab34213cacf40a783a4bf21573d769d2b166e078d35682d2e7bd36706fbd21ff0c5db714
+EBUILD qmplay2-23.06.17.ebuild 3309 BLAKE2B 957fdf4db921edc95266e6cb0192d36f46e2845a7f0d7ef33b955f83ac6767b0a906b79331957db84c4a5976e47fa7ff51e6dc7e98cb88d62adbab58885844bb SHA512 a6ed3fd72323b51cb4569d10eeefd78b2593725b5460451fff8f45aaf2df256e5d539b17f1b4444ec82bcc5ac432f63ddd61bc9eea3f5065ecdc6919f474a24f
 EBUILD qmplay2-9999.ebuild 3318 BLAKE2B bef41fcb3655faf0fb9d0d02014066cded54f3215db6a64944f152ef24a266cd7974894c7ba0573e6f427df1d9c715aaae369afa4a27ba49d034e97671af5ac2 SHA512 22b73ab2f2effee3cb6e494da91a421d12d30572b2343b667002419e57920af8ce93e39be5dc7d926f6222dc728db45c7e38c8cba6fcf9b9c40daaa42054e34c
 MISC metadata.xml 1287 BLAKE2B f04c4032dd3f32f10e33c551d364a9914d7663448b293ab9161da4741f53e65438749c1cd14b2ab0f5dd6a231109763642e53932d2705170a7e063e594acae36 SHA512 3f480f4d3cff62300e8eed043f16fe2a0f5cb8572be5fa00710b86036b93650b852168b7e01c2611c95755205d1a33883d67dfb8fd187d87c459d923e77c9fbd
diff --git a/media-video/qmplay2/qmplay2-23.06.17.ebuild b/media-video/qmplay2/qmplay2-23.06.17.ebuild
new file mode 100644
index 000000000000..41412c90d14c
--- /dev/null
+++ b/media-video/qmplay2/qmplay2-23.06.17.ebuild
@@ -0,0 +1,135 @@
+# Copyright 1999-2023 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=8
+
+inherit cmake xdg
+
+DESCRIPTION="A Qt-based video player, which can play most formats and codecs"
+HOMEPAGE="https://github.com/zaps166/QMPlay2"
+
+if [[ ${PV} == *9999 ]]; then
+	inherit git-r3
+	EGIT_REPO_URI="https://github.com/zaps166/QMPlay2"
+else
+	SRC_URI="https://github.com/zaps166/QMPlay2/releases/download/${PV}/QMPlay2-src-${PV}.tar.xz"
+	S="${WORKDIR}/QMPlay2-src-${PV}"
+	KEYWORDS="~amd64"
+fi
+
+LICENSE="LGPL-3"
+SLOT="0"
+
+IUSE="avdevice +audiofilters +alsa cdio cuvid extensions gme inputs libass
+	modplug notifications opengl pipewire portaudio pulseaudio sid shaders
+	+taglib vaapi vdpau videofilters visualizations vulkan xv"
+
+REQUIRED_USE="
+	audiofilters? ( || ( alsa pipewire portaudio pulseaudio ) )
+	shaders? ( vulkan )"
+
+RDEPEND="
+	dev-qt/qtcore:5
+	dev-qt/qtdbus:5
+	dev-qt/qtgui:5[X(-)]
+	dev-qt/qtsvg:5
+	dev-qt/qtwidgets:5
+	dev-qt/qtx11extras:5
+	media-video/ffmpeg
+	alsa? ( media-libs/alsa-lib )
+	cdio? ( dev-libs/libcdio[cddb] )
+	extensions? ( dev-qt/qtdeclarative:5 )
+	gme? ( media-libs/game-music-emu )
+	libass? ( media-libs/libass )
+	opengl? ( virtual/opengl )
+	pipewire? ( media-video/pipewire )
+	portaudio? ( media-libs/portaudio )
+	pulseaudio? ( media-libs/libpulse )
+	sid? ( media-libs/libsidplayfp )
+	shaders? ( >=media-libs/shaderc-2020.1 )
+	taglib? ( media-libs/taglib	)
+	vaapi? (
+		>=media-video/ffmpeg-4.1.3[vaapi]
+		media-libs/libva[X]
+	)
+	vdpau? ( media-video/ffmpeg[vdpau] )
+	videofilters? ( dev-qt/qtconcurrent:5 )
+	vulkan? (
+		>=dev-qt/qtgui-5.14.1:5[vulkan]
+		>=media-libs/vulkan-loader-1.2.133
+	)
+	xv? ( x11-libs/libXv )
+"
+DEPEND="${RDEPEND}"
+BDEPEND="dev-qt/linguist-tools:5"
+
+src_prepare() {
+	# disable compress man pages
+	sed -r \
+		-e 's/if\(GZIP\)/if\(TRUE\)/' \
+		-e 's/(install.+QMPlay2\.1)\.gz/\1/' \
+		-i src/gui/CMakeLists.txt || die
+
+	cmake_src_prepare
+}
+
+src_configure() {
+	local mycmakeargs=(
+		-DBUILD_WITH_QT6=Off
+		# core
+		-DUSE_LINK_TIME_OPTIMIZATION=false
+		-DUSE_UPDATES=OFF
+		-DUSE_ALSA=$(usex alsa)
+		-DUSE_AUDIOCD=$(usex cdio)
+		-DUSE_DBUS_SUSPEND=ON
+		-DUSE_FREEDESKTOP_NOTIFICATIONS=ON
+		-DUSE_LIBASS=$(usex libass)
+		-DUSE_NOTIFY=$(usex notifications)
+		-DUSE_OPENGL=$(usex opengl)
+		-DUSE_VULKAN=$(usex vulkan)
+		-DUSE_GLSLC=$(usex shaders)
+		-DUSE_XVIDEO=$(usex xv)
+
+		# ffmpeg
+		-DUSE_FFMPEG_AVDEVICE=$(usex avdevice)
+		-DUSE_FFMPEG_VAAPI=$(usex vaapi)
+		-DUSE_FFMPEG_VDPAU=$(usex vdpau)
+
+		# chiptune
+		-DUSE_CHIPTUNE_GME=$(usex gme)
+		-DUSE_CHIPTUNE_SID=$(usex sid)
+
+		# modules
+		-DUSE_AUDIOFILTERS=$(usex audiofilters)
+		-DUSE_CUVID=$(usex cuvid)
+		-DUSE_INPUTS=$(usex inputs)
+		-DUSE_MODPLUG=$(usex modplug)
+		-DUSE_PIPEWIRE=$(usex pipewire)
+		-DUSE_PORTAUDIO=$(usex portaudio)
+		-DUSE_PULSEAUDIO=$(usex pulseaudio)
+		-DUSE_TAGLIB=$(usex taglib)
+		-DUSE_VIDEOFILTERS=$(usex videofilters)
+		-DUSE_VISUALIZATIONS=$(usex visualizations)
+
+		# extensions
+		-DUSE_EXTENSIONS=$(usex extensions)
+	)
+
+	if use extensions; then
+		# Move inside an if, to remove unused option warning
+		mycmakeargs+=(
+			-DUSE_LASTFM=ON
+			-DUSE_LYRICS=ON
+			-DUSE_MEDIABROWSER=ON
+			-DUSE_MPRIS2=ON
+		)
+	fi
+
+	if [[ ${PV} == *9999 ]]; then
+		mycmakeargs+=( -DUSE_GIT_VERSION=true )
+	else
+		mycmakeargs+=( -DUSE_GIT_VERSION=false )
+	fi
+
+	cmake_src_configure
+}
-- 
cgit v1.2.3