From e23a08d0c97a0cc415aaa165da840b056f93c997 Mon Sep 17 00:00:00 2001
From: V3n3RiX <venerix@koprulu.sector>
Date: Fri, 8 Oct 2021 23:06:07 +0100
Subject: gentoo resync : 08.10.2021

---
 media-video/gaupol/gaupol-1.10.1.ebuild | 65 +++++++++++++++++++++++++++++++++
 1 file changed, 65 insertions(+)
 create mode 100644 media-video/gaupol/gaupol-1.10.1.ebuild

(limited to 'media-video/gaupol/gaupol-1.10.1.ebuild')

diff --git a/media-video/gaupol/gaupol-1.10.1.ebuild b/media-video/gaupol/gaupol-1.10.1.ebuild
new file mode 100644
index 000000000000..cc4e0d9d820e
--- /dev/null
+++ b/media-video/gaupol/gaupol-1.10.1.ebuild
@@ -0,0 +1,65 @@
+# Copyright 1999-2021 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=8
+
+PYTHON_COMPAT=( python3_{8..10} )
+DISTUTILS_USE_SETUPTOOLS=no
+
+inherit distutils-r1 virtualx xdg-utils
+
+DESCRIPTION="A subtitle editor for text-based subtitles"
+HOMEPAGE="https://otsaloma.io/gaupol/"
+SRC_URI="https://github.com/otsaloma/${PN}/archive/${PV}.tar.gz -> ${P}.tar.gz"
+
+LICENSE="GPL-2+"
+SLOT="0"
+KEYWORDS="~amd64 ~arm64 ~x86"
+IUSE="spell"
+
+RDEPEND="
+	app-text/iso-codes
+	dev-python/chardet[${PYTHON_USEDEP}]
+	dev-python/pygobject:3[${PYTHON_USEDEP}]
+	x11-libs/gtk+:3[introspection]
+	spell? ( app-text/gspell[introspection] )
+"
+BDEPEND="
+	sys-devel/gettext
+	test? (
+		app-dicts/myspell-en
+		app-text/enchant[hunspell]
+		app-text/gspell[introspection]
+	)
+"
+
+distutils_enable_tests pytest
+
+DOCS=( AUTHORS.md NEWS.md README.md README.aeidon.md )
+
+python_test() {
+	virtx pytest -vv
+}
+
+pkg_postinst() {
+	xdg_desktop_database_update
+	xdg_icon_cache_update
+	if [[ -z ${REPLACING_VERSIONS} ]]; then
+		elog "The integrated video player requires media-plugins/gst-plugins-gtk."
+		elog ""
+		elog "External video previewing support requires MPV, MPlayer or VLC."
+		if use spell; then
+			elog ""
+			elog "Spell-checking requires a dictionary, any of app-dicts/myspell-*"
+			elog "or app-text/aspell with the appropriate L10N variable."
+			elog ""
+			elog "Additionally, make sure that app-text/enchant has the correct flags enabled:"
+			elog "USE=hunspell for myspell dictionaries and USE=aspell for aspell dictionaries."
+		fi
+	fi
+}
+
+pkg_postrm() {
+	xdg_desktop_database_update
+	xdg_icon_cache_update
+}
-- 
cgit v1.2.3