From 9ee6d97c2883d42f204a533a8bc1f4562df778fb Mon Sep 17 00:00:00 2001
From: V3n3RiX <venerix@redcorelinux.org>
Date: Wed, 16 Sep 2020 09:32:48 +0100
Subject: gentoo resync : 16.09.2020

---
 media-sound/yarock/yarock-1.4.0-r1.ebuild | 61 +++++++++++++++++++++++++++++++
 1 file changed, 61 insertions(+)
 create mode 100644 media-sound/yarock/yarock-1.4.0-r1.ebuild

(limited to 'media-sound/yarock/yarock-1.4.0-r1.ebuild')

diff --git a/media-sound/yarock/yarock-1.4.0-r1.ebuild b/media-sound/yarock/yarock-1.4.0-r1.ebuild
new file mode 100644
index 000000000000..39414485b05d
--- /dev/null
+++ b/media-sound/yarock/yarock-1.4.0-r1.ebuild
@@ -0,0 +1,61 @@
+# Copyright 1999-2020 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=7
+
+inherit cmake
+
+MY_P="Yarock_${PV}_Sources"
+DESCRIPTION="Qt-based music player"
+HOMEPAGE="https://seb-apps.github.io/yarock/"
+SRC_URI="https://launchpad.net/${PN}/1.x/${PV}/+download/${MY_P}.tar.gz"
+
+LICENSE="GPL-3"
+SLOT="0"
+KEYWORDS="~amd64"
+IUSE="mpv phonon vlc"
+
+BDEPEND="
+	dev-qt/linguist-tools:5
+"
+RDEPEND="
+	dev-cpp/htmlcxx
+	dev-qt/qtcore:5
+	dev-qt/qtdbus:5
+	dev-qt/qtgui:5
+	dev-qt/qtnetwork:5
+	dev-qt/qtsql:5[sqlite]
+	dev-qt/qtwidgets:5
+	dev-qt/qtxml:5
+	media-libs/taglib
+	x11-libs/libX11
+	phonon? ( >=media-libs/phonon-4.11.0 )
+	vlc? ( media-video/vlc:= )
+"
+DEPEND="${RDEPEND}
+	dev-qt/qtconcurrent:5
+	dev-qt/qtx11extras:5
+"
+
+DOCS=( CHANGES.md README.md )
+
+S="${WORKDIR}/${MY_P}"
+
+src_prepare() {
+	cmake_src_prepare
+	sed -e "/^install.*org.yarock.appdata.xml/s:share/appdata:share/metadata:" \
+		-i CMakeLists.txt || die
+	sed -e "/^Version/d" \
+		-i data/org.yarock.desktop || die
+}
+
+src_configure() {
+	local mycmakeargs=(
+		-DENABLE_QT5=ON
+		-DENABLE_MPV=$(usex mpv)
+		-DENABLE_PHONON=$(usex phonon)
+		-DENABLE_VLC=$(usex vlc)
+	)
+
+	cmake_src_configure
+}
-- 
cgit v1.2.3