From 0f558761aa2dee1017b4751e4017205e015a9560 Mon Sep 17 00:00:00 2001
From: V3n3RiX <venerix@koprulu.sector>
Date: Wed, 29 Jun 2022 12:04:12 +0100
Subject: gentoo resync : 29.12.2022

---
 media-sound/rosegarden/rosegarden-22.06.ebuild | 62 ++++++++++++++++++++++++++
 1 file changed, 62 insertions(+)
 create mode 100644 media-sound/rosegarden/rosegarden-22.06.ebuild

(limited to 'media-sound/rosegarden/rosegarden-22.06.ebuild')

diff --git a/media-sound/rosegarden/rosegarden-22.06.ebuild b/media-sound/rosegarden/rosegarden-22.06.ebuild
new file mode 100644
index 000000000000..2a8fc820cf59
--- /dev/null
+++ b/media-sound/rosegarden/rosegarden-22.06.ebuild
@@ -0,0 +1,62 @@
+# Copyright 1999-2022 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=8
+
+inherit cmake xdg virtualx
+
+DESCRIPTION="MIDI and audio sequencer and notation editor"
+HOMEPAGE="https://www.rosegardenmusic.com/"
+SRC_URI="mirror://sourceforge/${PN}/${P}.tar.bz2"
+
+LICENSE="GPL-2"
+SLOT="0"
+KEYWORDS="~amd64 ~ppc ~x86"
+IUSE="lirc"
+
+BDEPEND="
+	dev-qt/linguist-tools:5
+	virtual/pkgconfig
+"
+RDEPEND="
+	dev-qt/qtcore:5
+	dev-qt/qtgui:5
+	dev-qt/qtnetwork:5
+	dev-qt/qtprintsupport:5
+	dev-qt/qtwidgets:5
+	dev-qt/qtxml:5
+	media-libs/alsa-lib:=
+	>=media-libs/dssi-1.0.0:=
+	media-libs/ladspa-sdk:=
+	media-libs/liblo:=
+	media-libs/liblrdf:=
+	media-libs/libsamplerate:=
+	media-libs/libsndfile:=
+	sci-libs/fftw:3.0
+	sys-libs/zlib:=
+	virtual/jack
+	x11-libs/libSM:=
+	lirc? ( app-misc/lirc:= )
+"
+DEPEND="${RDEPEND}
+	dev-qt/qttest:5
+"
+
+src_prepare() {
+	cmake_src_prepare
+}
+
+src_configure() {
+	local mycmakeargs=(
+		-DDISABLE_LIRC=$(usex !lirc)
+	)
+	cmake_src_configure
+}
+
+src_test() {
+	# bug 701682, tries to open network socket and fails.
+	local myctestargs=(
+		-E "(test_notationview_selection)"
+	)
+	virtx cmake_src_test
+}
-- 
cgit v1.2.3